mieki256's diary

Node2D
  │  
  ├─ Node2D
  │     │
  │     └─ Label
  │
  └─ AnimationPlayer

• フォントサイズ(Size)は32に。
• Use Filter を有効化。
• Font Data には res://resources/Aileron-Black.otf を指定した。
• Custom Colors → Font Color Shadow を有効化。
• Custom Constants → Shadow Offset x,y を (4,4)に。

export (PackedScene) var getitemeffect

        var effect = getitemeffect.instance()
        effect.position = body.position
        get_node("/root/Main").add_child(effect)

• Inherit : 上位ノードの設定を継承する。
• Stop : ポーズ有効時に自身の処理を止める。
• Process : ポーズ有効時も自身の処理を続行する。

• Mainノード : Mode = Process
• Playerノード : Mode = Process
• Appleノード : Mode = Stop
• Bombノード : Mode = Stop
• ItemGeneratorノード : Mode = Stop
• GetItemEffectノード : Mode = Stop

• ゲームオーバーになったタイミングでポーズ有効化。get_tree().paused = true を記述。
• ゲームタイトルを表示し直すタイミングでポーズ解除。get_tree().paused = false を記述。

kill_all_items()

func kill_all_items():
    get_tree().call_group("apples", "queue_free")
    get_tree().call_group("bombs", "queue_free")
    get_tree().call_group("effects", "queue_free")

> python --version
Python 3.8.6

> python -VV
Python 3.8.6 (tags/v3.8.6:db45529, Sep 23 2020, 15:52:53) [MSC v.1927 64 bit (AMD64)]

python -m http.server

python -m SimpleHTTPServer

AddType application/octet-stream pck
AddType application/wasm wasm

今回措置命令を受けたのは、アガスタ、エコリカ、エディオン、オーム電機、グリーンハウス、恵安、光波、コーナン商事、スリー・アールシステム、セントレードM.E.、タキオン、リーダーメディアテクノ。この12社は、消費者に販売するLED電球において、商品パッケージに「白熱電球60W形相当の明るさ」など、白熱電球と比較した明るさを表示していたが、実際には白熱電球と同等の明るさは得られなかったという。

消費者庁、LED電球の明るさを誇大表示した12社に再発防止命令 - 家電 Watch より

3c:f8:19
dc:04:00

C:\Users\<USERNAME>\AppData\Roaming\Blender Foundation\Blender\2.83\scripts\addons\

• Material Mode を「Script Shader Material」にしたり。
• Generate External Material のチェックを入れたり入れなかったり。
• Material Search Paths を「Project Directory」にし直したり。

KinematicBody
  │
  ├─ MeshInstance
  │
  └─ CollisopnShape

Player (KinematicBody)
  │
  ├─ PlayerModel (MeshInstance)
  │     │
  │     ├─ MeshInstance
  │     │
  │     └─ MeshInstance
  │
  └─ CollisopnShape

extends KinematicBody

const SPEED = 32
var velocity = Vector3()

func _ready():
    pass # Replace with function body.

#func _process(delta):
#   pass

func _physics_process(delta):
    # move
    velocity = Vector3()
    if Input.is_action_pressed("ui_right"):
        velocity.x = 1
    elif Input.is_action_pressed("ui_left"):
        velocity.x = -1
    if Input.is_action_pressed("ui_down"):
        velocity.z = 1
    elif Input.is_action_pressed("ui_up"):
        velocity.z = -1
    
    # Do not multiply by delta when using move_and_slide()
    velocity = velocity.normalized() * SPEED
    move_and_slide(velocity)

• KinematicBodyノードを使ってる場合は、_process(delta) ではなく _physics_process(delta) の中に移動処理等を書く。
• Input.is_action_pressed("ui_right") で、カーソルキーの右キーが押されているか判別できる。
• move_and_slide(velocity) で velocity の方向に移動する。delta は掛けなくてよい。

• ルートノード(Bg)の下に BgModel という名前の Spatial を作成して、その中に全体を入れておく。
• z軸方向にパターン(?)が繰り返すような形にしておく。

Bg (Spatial)
│
└─ BgModel (Spatial)
       │
       ├─ Spatial1
       ├─ Spatial2 (Spatial1 を複製)
       └─ Spatial3 (Spatial1 を複製)

extends Spatial

export var scroll_speed = 30
export var limit_z = 40
export var add_z = -40

func _ready():
    pass # Replace with function body.

func _process(delta):
    $BgModel.translation.z += scroll_speed * delta
    if $BgModel.translation.z >= limit_z:
        $BgModel.translation.z += add_z

Area
  ├─ Spatial
  │     ├─ MeshInstance
  │     └─ MeshInstance
  └─ CollisionShape

• Wait Time を 2 に。
• One Shot にチェックを入れて有効化。
• Autostart にチェックを入れて有効化。

extends Area

var velocity = Vector3()
var speed = 90

func _ready():
    velocity = Vector3(0, 0, -1)

#func _process(delta):
#   pass

func _physics_process(delta):
    translate(velocity * speed * delta)

func _on_Timer_timeout():
    queue_free()

• Wait Time は 0.065 に。高橋名人が1秒間に16連射していたらしいので、それに近い値を指定してみたつもり。
• Autostart にチェックを入れて有効化。

extends KinematicBody

export (PackedScene) var PlayerBullet

const SPEED = 32
var velocity = Vector3()

func _ready():
    pass # Replace with function body.

#func _process(delta):
#   pass

func _physics_process(delta):
    # move
    velocity = Vector3()
    if Input.is_action_pressed("ui_right"):
        velocity.x = 1
    elif Input.is_action_pressed("ui_left"):
        velocity.x = -1
    if Input.is_action_pressed("ui_down"):
        velocity.z = 1
    elif Input.is_action_pressed("ui_up"):
        velocity.z = -1
    
    # Do not multiply by delta when using move_and_slide()
    velocity = velocity.normalized() * SPEED
    move_and_slide(velocity)

func _on_ShotTimer_timeout():
    var bullet = PlayerBullet.instance()
    bullet.translation = Vector3(translation.x, translation.y, translation.z - 1.0)
    get_tree().root.get_node("Main/PlayerBullets").add_child(bullet)

• 最初のほうで、export (PackedScene) var PlayerBullet を書いて、PlayerBulletシーンを入れておく変数 PlayerBullet を用意する。
• _on_ShotTimer_timeout() の中でプレイヤーの弾の発生処理をする。PlayerBullet のインスタンスを生成、座標を Player のちょっと前に設定してから、Mainシーンの PlayerBulletsノードに登録している。

EnemyZako (Area)
  │
  ├─ EnemyZakoModel (Spatial)
  │     │
  │     └─ MeshInstance
  │
  ├─ CollisionShape
  │
  └─ ShotTimer (Timer)

extends Area

export (PackedScene) var enemybullet

var base_pos = Vector3()
var angle = 0
export var move_w = 22
export var move_h = 12

func _ready():
    base_pos = translation
    angle = 0

#func _process(delta):
#   pass

func _physics_process(delta):
    move(delta)
    
func move(delta):
    angle += delta
    translation.x = base_pos.x + move_w * cos(deg2rad(angle * 90))
    translation.z = base_pos.z + move_h * sin(deg2rad(angle * 70))

EnemyBullet (Area)
  │
  ├─ MeshInstance
  │
  ├─ CollisonShape
  │
  └─ KillTimer (Timer)

• Wait Time を 3 に。
• Autostart を有効化。

extends Area

var velocity = Vector3()
var direction = 0
var speed = 3

func _ready():
    pass # Replace with function body.

#func _process(delta):
#   pass

func _physics_process(delta):
    translate(velocity * speed * 60 * delta)

func set_dir_and_speed(angle, spd):
    direction = angle
    speed = spd
    var x = cos(deg2rad(angle))
    var z = sin(deg2rad(angle))
    velocity = Vector3(x, 0, z)
    
func _on_KillTimer_timeout():
    queue_free()

• Timerノードを追加して、ShotTimer にリネーム。
• スクリプトファイル EnemyZako.gd の最初のあたりに、export (PackedScene) var enemybullet を追記。

• Wait Time を 1 に。1秒毎に敵弾を発生させる。
• Autostart を有効化。

extends Area

export (PackedScene) var enemybullet

var base_pos = Vector3()
var angle = 0
export var move_w = 22
export var move_h = 12
var bullets

func _ready():
    base_pos = translation
    angle = 0
    bullets = get_tree().root.get_node("Main/EnemyBullets")

#func _process(delta):
#   pass

func _physics_process(delta):
    move(delta)
    
func move(delta):
    angle += delta
    translation.x = base_pos.x + move_w * cos(deg2rad(angle * 90))
    translation.z = base_pos.z + move_h * sin(deg2rad(angle * 70))
    
func _on_ShotTimer_timeout():
    var angle_add = 12
    var angle = 90 - angle_add * 3
    var spd = 0.2
    for i in range(7):
        _shot(translation, angle, spd)
        _shot(translation, angle, spd * 0.8)
        angle += angle_add
    
func _shot(pos, angle, spd):
    var bullet = enemybullet.instance()
    bullet.translation = pos
    bullet.set_dir_and_speed(angle, spd)
    bullets.add_child(bullet)

• Radius で、球のモデルの半径を指定。
• Height で、球のモデルの高さを指定。
• Radial Segments と Rings で、球のモデルにどのくらいポリゴン数を使うかを指定。多ければ滑らかな球になるし、少なくすればガクガクした球になる。

• player (プレイヤー)
• playerbullets (プレイヤーの弾)
• enemy (敵)
• enemybullets (敵弾)

• プレイヤーキャラなので、Layer は一番左の player を有効化。
• Mask でアタリ判定(衝突判定)をする対象を選ぶ。プレイヤーキャラは、「自分には当たらない」「自分の弾にも当たらない」「敵とは当たる」「敵弾にも当たる」ので、左から3番目の enemy と、左から4番目の enemybullets を有効化。

• プレイヤーの弾なので、Layer は左から2番目の playerbullets を有効化。
• Mask は、「プレイヤーには当たらない」「自分(達)にも当たらない」「敵には当たる」「敵弾とは当たらない」ので、左から3番目の enemy だけを有効化。

• 敵なので、Layer は左から3番目の enemy を有効化。
• Mask は、「プレイヤーには当たる」「プレイヤーの弾にも当たる」「自分には当たらない」「自分の弾にも当たらない」ので、一番左の player と、左から2番目の playerbullets を有効化。

• 敵弾なので、Layer は左から4番目の enemybullets を有効化。
• Mask は、「プレイヤーには当たる」「プレイヤーの弾には当たらない」「敵には当たらない」「自分(達)にも当たらない」ので、一番左の player だけを有効化。

extends Area

var velocity = Vector3()
var speed = 90

func _ready():
    velocity = Vector3(0, 0, -1)

#func _process(delta):
#   pass

func _physics_process(delta):
    translate(velocity * speed * delta)

func _on_Timer_timeout():
    queue_free()

func _on_PlayerBullet_area_entered(area):
    if is_queued_for_deletion():
        return
    print("PlayerBullet Hit!")
    queue_free()

• とりあえず仮の処理として、print() を呼んで当たったことを示すメッセージを出力してみる。
• プレイヤーの弾が敵に当たったら、その場でプレイヤーの弾は消滅してほしいので、自分を消去する queue_free() を呼んでおく。
• is_queued_for_deletion() は、自分に消去処理が要求されているかを調べることができる。もし自分が消去予定になっていたら、何も処理をせずにメソッドを抜けるようにしてある。

    # print("PlayerBullet Hit!")

extends Area

var velocity = Vector3()
var direction = 0
var speed = 3

func _ready():
    pass # Replace with function body.

#func _process(delta):
#   pass

func _physics_process(delta):
    translate(velocity * speed * 60 * delta)

func set_dir_and_speed(angle, spd):
    direction = angle
    speed = spd
    var x = cos(deg2rad(angle))
    var z = sin(deg2rad(angle))
    velocity = Vector3(x, 0, z)
    
func _on_KillTimer_timeout():
    queue_free()

func _on_EnemyBullet_body_entered(body):
    if is_queued_for_deletion():
        return
    print("EnemyBullet Hit!")
    queue_free()

    # print("EnemyBullet Hit!")

• body_entered(body: Node) シグナルにメソッドを接続すれば、そのメソッドにプレイヤーと当たった時の処理を書ける。
• area_entered(area: Area) シグナルにメソッドを接続すれば、そのメソッドにプレイヤーの弾と当たった時の処理を書ける。

extends Area

export (PackedScene) var enemybullet

var base_pos = Vector3()
var angle = 0
export var move_w = 22
export var move_h = 12
var bullets

func _ready():
    base_pos = translation
    angle = 0
    bullets = get_tree().root.get_node("Main/EnemyBullets")

#func _process(delta):
#   pass

func _physics_process(delta):
    move(delta)
    
func move(delta):
    angle += delta
    translation.x = base_pos.x + move_w * cos(deg2rad(angle * 90))
    translation.z = base_pos.z + move_h * sin(deg2rad(angle * 70))
    
func _on_ShotTimer_timeout():
    var angle_add = 12
    var angle = 90 - angle_add * 3
    var spd = 0.2
    for i in range(7):
        _shot(translation, angle, spd)
        _shot(translation, angle, spd * 0.8)
        angle += angle_add
    
func _shot(pos, angle, spd):
    var bullet = enemybullet.instance()
    bullet.translation = pos
    bullet.set_dir_and_speed(angle, spd)
    bullets.add_child(bullet)

func _on_EnemyZako_area_entered(area):
    if is_queued_for_deletion():
        return
    print("playerbullet hit the enemy")

func _on_EnemyZako_body_entered(body):
    if is_queued_for_deletion():
        return
    print("player hit the enemy")

Hud (Control)
  │
  ├─ PlayerHp (Label)
  │
  └─ EnemyHp (Label)

• Size で文字サイズを指定。
• Use Filter を有効にすれば文字が少し滑らかになって表示される。
• Font Color Shadow を有効にすれば文字に影がつく。
• Shadow Offset X, Y で影のオフセット位置を変更できる。

extends Control

func _ready():
    pass # Replace with function body.

#func _process(delta):
#   pass

func update_player_hp(hp, hpmax):
    $PlayerHp.text = "Player: %d/%d" % [hp, hpmax]
    
func update_enemy_hp(hp, hpmax):
    $EnemyHp.text = "Enemy: %d/%d" % [hp, hpmax]

extends Node

var player_hp_max = 0
var enemy_hp_max = 0

func _ready():
    player_hp_max = $Player.hp
    enemy_hp_max = $EnemyZako.hp

#func _process(delta):
#   pass

func damage_player():
    var hp = $Player.hp
    $Hud.update_player_hp(hp, player_hp_max)

func damage_enemy():
    var hp = $EnemyZako.hp
    $Hud.update_enemy_hp(hp, enemy_hp_max)

• 初期化時に Player や Enemy のHPを取得して変数に記録。
• Player 又は Enemy がダメージを受けた際、現在のHPを使ってHP表示を更新するメソッドを用意。

extends KinematicBody

signal player_damaged
signal player_died

# export (PackedScene) var PlayerBullet
var PlayerBullet = preload("res://assets/PlayerBullet.tscn")

const SPEED = 32
var velocity = Vector3()
var bullets

var hp = 50
var damage = 0

func _ready():
    hp = 50
    # bullets = get_tree().root.get_node("Main/PlayerBullets")
    bullets = $"/root/Main/PlayerBullets"

#func _process(delta):
#   pass

func _physics_process(delta):
    # move
    velocity = Vector3()
    if Input.is_action_pressed("ui_right"):
        velocity.x = 1
    elif Input.is_action_pressed("ui_left"):
        velocity.x = -1
    if Input.is_action_pressed("ui_down"):
        velocity.z = 1
    elif Input.is_action_pressed("ui_up"):
        velocity.z = -1
    
    # Do not multiply by delta when using move_and_slide()
    velocity = velocity.normalized() * SPEED
    move_and_slide(velocity)
    
    if damage > 0:
        hp -= damage
        damage = 0
        if hp <= 0:
            hp = 0
            emit_signal("player_died")
        emit_signal("player_damaged")

func _on_ShotTimer_timeout():
    var bullet = PlayerBullet.instance()
    var pos = Vector3(translation.x, translation.y, translation.z - 1.5)
    bullet.translation = pos
    bullets.add_child(bullet)

• 最初のあたりで、カスタムシグナルとして signal player_damaged と signal player_died を用意した。
• hp という変数を用意した。
• damage という変数を用意した。
• 別の何かが damage に 0以外の値を入れたら、自分はその分ダメージを受けたのだ、ということにする。
• hp から damage 分を引いて、hp が 0 になってなければ自分はまだ生きてる。0なら死んでる。
• ダメージを受けた時は emit_signal("player_damaged") を呼んで player_damaged シグナルを発行する。
• 死んだ時は emit_signal("player_died") を呼んで player_died シグナルを発行する。

extends Area

signal enemy_damaged
signal enemy_died

export (PackedScene) var enemybullet

var base_pos = Vector3()
var angle = 0
export var move_w = 22
export var move_h = 12
var bullets

var hp = 990
var damage = 0
var attack_point = 10

func _ready():
    base_pos = translation
    angle = 0
    bullets = get_tree().root.get_node("Main/EnemyBullets")

#func _process(delta):
#   pass

func _physics_process(delta):
    move(delta)
    
func move(delta):
    angle += delta
    translation.x = base_pos.x + move_w * cos(deg2rad(angle * 90))
    translation.z = base_pos.z + move_h * sin(deg2rad(angle * 70))
    
func _on_ShotTimer_timeout():
    var angle_add = 12
    var angle = 90 - angle_add * 3
    var spd = 0.2
    for i in range(7):
        _shot(translation, angle, spd)
        _shot(translation, angle, spd * 0.8)
        angle += angle_add
    
func _shot(pos, angle, spd):
    var bullet = enemybullet.instance()
    bullet.translation = pos
    bullet.set_dir_and_speed(angle, spd)
    bullets.add_child(bullet)

func _on_EnemyZako_area_entered(area):
    if is_queued_for_deletion():
        return
    # print("playerbullet hit the enemy")
    if area.is_in_group("playerbullets"):
        hp -= area.attack_point
        if hp <= 0:
            hp = 0
            emit_signal("enemy_died")
        emit_signal("enemy_damaged")

func _on_EnemyZako_body_entered(body):
    if is_queued_for_deletion():
        return
    # print("player hit the enemy")
    if body.is_in_group("player"):
        body.damage = attack_point

extends Area

var velocity = Vector3()
var direction = 0
var speed = 3
var attack_point = 10

func _ready():
    pass # Replace with function body.

#func _process(delta):
#   pass

func _physics_process(delta):
    translate(velocity * speed * 60 * delta)

func set_dir_and_speed(angle, spd):
    direction = angle
    speed = spd
    var x = cos(deg2rad(angle))
    var z = sin(deg2rad(angle))
    velocity = Vector3(x, 0, z)
    
func _on_KillTimer_timeout():
    queue_free()

func _on_EnemyBullet_body_entered(body):
    if is_queued_for_deletion():
        return
    # print("EnemyBullet Hit!")
    if body.is_in_group("player"):
        body.damage = attack_point
    queue_free()

• 変数 attack_point を追加して、プレイヤーへの攻撃力を入れておく。
• プレイヤーと当たった時は、プレイヤーが変数 damage を持っているはずだから、damage に自分の攻撃力を入れてやる。
• プレイヤー側は、damage が0以外なら何かが当たってダメージを受けたという処理をする。

extends Area

var velocity = Vector3()
var speed = 90

var attack_point = 10

func _ready():
    velocity = Vector3(0, 0, -1)

#func _process(delta):
#   pass

func _physics_process(delta):
    translate(velocity * speed * delta)

func _on_Timer_timeout():
    queue_free()

func _on_PlayerBullet_area_entered(area):
    if is_queued_for_deletion():
        return
    # print("PlayerBullet Hit!")
    queue_free()

• 変数 attack_point を追加して、敵への攻撃力を入れておく。
• 敵と当たった時は、敵側でこの attack_point を参照して処理をする。

• Wait Time を 2 に。
• One Shot を有効化。

• Wait Time を 0.05 に。

1. DmagaeTimer や BlinkTimer を選んでから、ノードタブをクリック → シグナルをクリック。
2. timeout を右クリックして「接続」。
3. Player を選んで「接続」。

# ...

var damaging = false

func _ready():
    # ...

    damage = 0
    damaging = false

    # ...

func _physics_process(delta):

    # ...

    if not damaging:
        if damage > 0:
            hp -= damage
            damage = 0
            if hp <= 0:
                hp = 0
            emit_signal("player_damaged")
            damaging = true
            $DamageTimer.start()
            $BlinkTimer.start()

# ...

func _on_DamageTimer_timeout():
    $BlinkTimer.stop()
    damage = 0
    damaging = false
    visible = true
    if hp <= 0:
        hp = 0
        emit_signal("player_died")

func _on_BlinkTimer_timeout():
    visible = not visible

• ダメージ中を示すフラグ、damaging を用意。
• ダメージ中は、自分がダメージを受けたかどうかは判定しない。
• ダメージを受けたら、ダメージ中フラグを立ててから、$DamageTimer.start()、$BlinkTimer.start() を呼んで、2つの Timer を開始させる。
• BlinkTimer は指定した時間間隔で timeoutシグナルを何度も繰り返し発行する。そのたびに _on_BlinkTimer_timeout() が呼ばれる。このメソッドの中で、visibleプロパティを反転させて、表示と非表示を切り替えている。
• DmagaeTimer は指定時間が経過すると timeoutシグナルを1回だけ発行。_on_DamageTimer_timeout() が呼ばれる。BlinkTimerを停止させて、ダメージ中フラグを降ろして、表示を有効化。

• Color を RGBA=(255, 255, 255, 200) に。
• Size x, y を (1280, 720) に。ゲームウインドウ全体を覆いつくすサイズを指定。

• Wait Time を 0.125 に。0.125秒だけ Flash を表示させる。
• One Shot を有効化。

1. FlashTimer を選択してから、ノードタブをクリック → シグナルをクリック。
2. timeout を右クリックして「接続」。
3. Hud を選択して「接続」。

# ...

func _ready():
    $Flash.visible = false

# ...

func start_flash():
    $Flash.visible = true
    $FlashTimer.start()
    
func _on_FlashTimer_timeout():
    $Flash.visible = false

• 初期化処理時に Flashノードを非表示にする。
• 画面フラッシュを開始するメソッド、start_flash() を追加。Flashノードの表示を有効化して、FlashTimer を開始している。
• FlashTimer は指定時間が経過すると timeout シグナルを発行して _on_FlashTimer_timeout() が呼ばれる。Flashノードを非表示にする。

# ...

func damage_player():
    # ...
    $Hud.start_flash()

# ...

• プレイヤーがダメージを受けると Main.gd内の damage_player() が呼ばれる。その中で $Hud.start_flash() を呼んで Hud の画面フラッシュを開始させる。

# ...

var damage_timer = 0

var rnd = RandomNumberGenerator.new()

func _ready():
    # ...

    damage = 0
    damage_timer = 0

    # ...

func _physics_process(delta):
    # ...
    check_damage()
    damaging_animation(delta)
    
# ...

func check_damage():
    if damage > 0:
        hp -= damage
        damage = 0
        damage_timer = 0.25
        if hp <= 0:
            hp = 0
            emit_signal("enemy_died")
        emit_signal("enemy_damaged")

func damaging_animation(delta):
    if damage_timer > 0:
        damage_timer -= delta
        var target_mesh = $EnemyZakoModel
        if damage_timer <= 0:
            damage_timer = 0
            target_mesh.translation = Vector3()
        else:
            var r = 0.5
            var x = rnd.randf_range(-r, r)
            var z = rnd.randf_range(-r, r)
            target_mesh.translation = Vector3(x, 0, z)

# ...
            
func _on_EnemyZako_area_entered(area):
    if is_queued_for_deletion():
        return
    # print("playerbullet hit the enemy")
    if area.is_in_group("playerbullets"):
        damage = area.attack_point

# ...

• var rnd = RandomNumberGenerator.new() で疑似乱数生成器を用意する。
• rnd.randf_range(-r, r) で、-r から r の範囲で乱数を生成。
• 自分(EnemyZako)の座標ではなく、その下にぶら下がってる EnemyZakoModel(表示モデルを担当)の位置をずらしている。
• 時間経過を、Timerノードを使わずにスクリプト内の処理で測っている。

Title (Node2D)
  │
  └─ CanvasLayer
         │
         ├─ ColorRect
         │
         ├─ Label
         │
         └─ Button

• ColorRect で指定色の矩形を描画できる。青色にして、画面一杯に表示される size にした。
• Label で文字を描画できる。ゲームのタイトル「Simple Shoot'Em Up」を表示させた。使ったフォントは Vegur-Bold.otf。
• Button でマウスクリックに反応するボタンを置ける。「START」と表示させて下のほうに配置した。

1. Button を選択
2. ノードタブをクリック → シグナルをクリック
3. pressed() を右クリックして「接続」
4. Title を選択して「接続」

extends Node2D

func _ready():
    pass # Replace with function body.

#func _process(delta):
#   pass

func _on_Button_pressed():
    get_tree().change_scene("res://Main.tscn")

• get_tree().change_scene("res://Main.tscn") で、res://Main.tscn にシーンを切り替える、という指定をしている。

1. Shortcut の横の「空」をクリックして「新規 Shortcut」を選択。
2. 作成された「Shortcut」をクリックするとその下にもShortcutの欄が出てくる。
3. 横の「空」をクリックして「新規 InputEventAction」を選択。
4. 作成された「InputEventAction」をクリックするとその下に Action 等が出てくる。
5. Action に「ui_accept」と入力。

• ui_accept には、デフォルトでスペースキーやEnterキーが割り当てられている。プロジェクト設定で変更できる。

extends Node2D

func _ready():
    pass # Replace with function body.

func _on_Button_pressed():
    get_tree().change_scene("res://Title.tscn")

• get_tree().change_scene("res://Title.tscn") を呼ぶことで、res://Title.tscn にシーンを切り替える。

1. GameOver、または YouWin を選択
2. ノードタブをクリック → シグナルをクリック
3. pressed() を右クリックして「接続」
4. スクリプト GoToTitle.gd をアタッチしているノード(GameOver、YouWin)を選択
5. メソッド名には _on_Button_pressed を入力して「接続」

# ...

func die_player():
    get_tree().change_scene("res://GameOver.tscn")
    
func die_enemy():
    get_tree().change_scene("res://YouWin.tscn")

• ゲームオーバー画面にシーンを切り替えるメソッド、die_player() を追加。
• ステージクリア画面にシーンを切り替えるメソッド、die_enemy() を追加。

1. ノードタブをクリック → シグナルをクリック
2. player_died() を右クリックして「接続」

• 上記ページ内の、「Code」と書かれた緑色のボタンをクリック → 「Download ZIP」を選択。godot-blender-exporter-master.zip がダウンロードできる。
• 解凍して、io_scene_godot というフォルダを blender のユーザ設定フォルダにコピーすればインストールできる。

C:\Users\<ユーザアカウント名>\AppData\Roaming\Blender Foundation\Blender\2.83\scripts\addons\

• blender を起動して、編集 → プリファレンス → アドオン。
• 検索欄に「godot」と打ち込めば「Import-Export: Godot Engine Exporter」がリストアップされる。
• チェックを入れて有効化。

• enemy_type_b_fix の位置、大きさ、向きを調整。
• enemy_type_b_fixノードを EnemyZakoModel の下に配置。
• 今まで表示していた仮モデルは非表示にする。
• CollisionShape を選択してアタリ範囲を修正。

extends Spatial

export var scroll_speed = 120
export var limit_z = 80
export var add_z = -80

export var angle_add = 20
export var x_shift_range = 80
export var rotz_range = 10
var angle = 0

func _ready():
    pass # Replace with function body.

func _process(delta):
    angle += (angle_add * delta)
    if angle > 360.0:
        angle -= 360.0
        
    var rz = rotz_range * sin(deg2rad(sin(deg2rad(-angle))))
    $BgModel.rotation.z = rz
    $BgModel.translation.x = x_shift_range * sin(deg2rad(angle))
    
    $BgModel.translation.z += scroll_speed * delta
    if $BgModel.translation.z >= limit_z:
        $BgModel.translation.z += add_z

# ...
            
func _on_ShotTimer_timeout():
    var angle_add = 12
    var angle = 90 - angle_add * 3
    var spd = 0.2
    for i in range(7):
        _shot(translation, angle, spd)
        if hp <= hpmax * 0.7:
            _shot(translation, angle, spd * 0.8)
        if hp <= hpmax * 0.3:
            _shot(translation, angle, spd * 1.2)
            _shot(translation, angle, spd * 1.1)
            _shot(translation, angle, spd * 0.9)
        angle += angle_add
    
# ...

• 敵のHPに応じて、発射する弾の数を変えている。

• ファイル一覧ウインドウから bgm.ogg をドラッグアンドドロップ。
• あるいは、Stream の横の「空」をクリックして「読込み」→ bgm.ogg を選択。

• DamageSe の Stream に enemy_damage_se.wav を指定。
• ShotSe の Stream に enemy_shot_se.wav を指定。

• CPU : AMD Ryzen 7 1700
• GPU (videocard) : NVIDIA GeForce GTX 1060 6GB
• RAM (Memory) : 16GB
• OS : Windows10 x64 2004

• Mozila Firefox 82.0.3 ... ガクガク状態。見るからに酷い。それでもまあ、一応は動いてくれた。
• Google Chrome 87.0.4280.66 ... 比較的滑らかに動く。ヌルヌル。
• Microsoft Edge 86.0.622.69 ... Google Chrome ほど滑らかではなく時々ガクッとするけれど Firefox ほどガクガクではない。
• Vivaldi 3.4.2066.106 ... Microsoft Edge と似たような感じ。

• userChrome.css の有効化 : toolkit.legacyUserProfileCustomizations.stylesheets を true に。
• userChrome.css の新規作成。about:profiles を開いてプロファイルフォルダを開き、ルートフォルダ内に chrome フォルダを新規作成して、その中に userChrome.css を新規作成。

/* Hide "Saved to Library!" bookmark confirmation popup */
#confirmation-hint { display: none !important; }

• GLES3 を使ってる場合は、GPUを使って処理をする Particles2D を選べる。
• GLES2 を使ってる場合は、CPUを使って処理をする CPUParticles2D を使う。ただしパフォーマンスは落ちるらしい。

• Emitting : パーティクルを発生させるかさせないか。true か false で変えられる
• Amount : パーティクル発生数
• Lifetime : パーティクルの生存時間。単位は秒
• OneShot : 有効なら1回だけ発生させて自身を消滅させる
• Speed Scale : 速度スケール。値が大きくなれば早くなるし、小さくなれば遅くなる
• Explosiveness : 0ならポポポポと連続で発生。1ならバッと一気に発生。0.x ならポポッ…と発生
• Local Coords : 有効なら、発生元の座標を基準にしながら動く。無効ならグローバル座標で動く
• Texture : パーティクル1つあたりで表示する画像ファイルを指定
• Emission Shape : 発生元の形状。Point なら1点から発生。Box なら矩形範囲の中で発生
• Direction - Direction : パーティクルを発射する方向を指定
• Direction - Spread : 方向に対して -α - +αの角度で発生。180度を指定すれば全方向に発射するようになる
• Gravity : 重力
• Initial Velocity - Velocity : 初期速度
• Linear Accel - Accel : 加減速度。マイナス値なら減速。プラス値なら加速
• Angle - Angle : 初期表示角度
• Scale Amount : 初期表示サイズ
• Scale Amount Curve : 表示サイズが変化していく様子をグラフで指定

• 「xxx Random」は、xxx をランダムに変化させる割合を指定できる。
• 「xxx Curve」は、xxx の変化の仕方をグラフで指定できる。「空」をクリックして「新規 Curve」を選べばカーブを作成できる。
• カーブ(グラフ？)の中で右クリック → 「ポイントを追加」を選べば制御点を増やせる。
• ポイント(制御点)をクリックすれば傾きを指定する線が出てくるので、ドラッグしてカーブの形を変えられる。

Main (Node)
│
├─ ParallaxBackground
│     │
│     ├─ ParallaxLayer
│     │     │
│     │     └─ TileMap
│     │
│     ├─ ParallaxLayer
│     │     │
│     │     └─ TileMap
│     │
│     └─ ParallaxLayer
│            │
│            └─ TileMap
│       
└─ Sprite
       │
       └─ Camera2D

• Current にチェックを入れて有効化すると、そのCamera2Dで指定された範囲がウインドウに表示される模様。
• Limit に値を指定すれば、その範囲内だけを表示する状態になる。
• Smoothing にチェックを入れれば、カメラが動く時に若干動きが遅れて滑らかなカメラの動きになる。

• 「カリ城」ではルパンがおじさんキャラになってるけれど、何がパート2だよ、ケッ。今更ルパンでもないだろ、アイツはもうおじさんみたいなもんだろうが、という意識がああいうルパン像に繋がっていくわけで。たしか緑ジャケットにしたのもパート2の否定だったような…。違ったかな…。
• 「アルバトロス」の中で見せたバリバリにアクションする不二子像は、パート2の不二子像の否定から出てきているし。
• パート2最終回では「お前達が今まで見ていたパート2のルパンは全部偽ルパンだったんだよ！」と言い出すし。嘘じゃないです。インタビュー記事で語ってますから。さすがに後になって「アレはやり過ぎだった…」「自分は何様のつもりなのか…」と反省してましたけど。

• プレイヤーキャラは KinematicBody2D が担当。
• BGアタリを担当する TileMap は、背景の多重スクロールを担当する ParallaxBackground, ParallaxLayer の中に入れてしまうと正常動作しない。プレイヤーキャラと同階層に置いたら期待通りの動作をしてくれた。
• 単に表示するだけでアタリ判定をしないBGについては、ParallaxBackground, ParallaxLayer の中に入れてしまって問題無い。

extends KinematicBody2D

export var walk_force = 2000.0
export var walk_max_speed = 400.0
export var stop_force = 1600.0
export var jump_speed = 960.0

var velocity = Vector2()
var gravity
var jumping = false

func _ready():
    gravity = ProjectSettings.get_setting("physics/2d/default_gravity")

#func _process(delta):
#   pass

func _physics_process(delta):
    var right = Input.get_action_strength("move_right")
    var left = Input.get_action_strength("move_left")
    var input = right - left
    var walk = walk_force * input
    if abs(walk) < walk_force * 0.2:
        velocity.x = move_toward(velocity.x, 0, stop_force * delta)
        # velocity.x = 0
    else:
        velocity.x += walk * delta
        # velocity.x = walk_max_speed * input
    velocity.x = clamp(velocity.x, -walk_max_speed, walk_max_speed)
    velocity.y += gravity * delta

    var snap = Vector2(0, 32)
    if is_on_floor():
        jumping = false
        if Input.is_action_pressed("move_up"):
            velocity.y = -jump_speed
            jumping = true
            snap = Vector2.ZERO
    else:
        snap = Vector2.ZERO
        
    velocity = move_and_slide_with_snap(velocity, snap, Vector2.UP, true, 4, deg2rad(60))
    # velocity = move_and_slide(velocity, Vector2.UP)
    
    _set_label_text("velo: (%.2f, %.2f)" % [velocity.x, velocity.y])
    
    if right > 0.5:
        $Sprite.flip_h = false
    if left > 0.5:
        $Sprite.flip_h = true
    
    if jumping:
        $Sprite.frame = 2
    elif is_on_floor():
        $Sprite.frame = 0
    else:
        $Sprite.frame = 1

func _set_label_text(t):
    $Label.text = t

• gravity = ProjectSettings.get_setting("physics/2d/default_gravity") で、プロジェクト設定の default_gravity を読み取ってる。
• KinematicBody2D は一定の時間間隔で _physics_process(delta) を呼び出すので、その中に移動処理を書く。
• _process(delta) も一定の時間間隔で呼ばれるけれど、状況によっては物理計算・衝突判定が正しく行われないのだとか。アタリを持ってるオブジェクトは _physics_process(delta) 内で処理をせよ、ということになっているらしい。
• Input.get_action_strength("xxx") で、xxxキーやxxxボタンを押したかどうかが 0 〜 1 の値で得られる。アナログジョイスティックを割り当てた時には、おそらく 0.n の値が返ってくるのではないか。たぶん。
• velocity = move_and_slide_with_snap() でBGアタリとの衝突判定＋補正処理をする。内部で delta を使って計算しているらしいので、与えるベクトルに対して事前に delta を掛けておかなくてもいい。
• move_and_slide*() を呼んでおけば、is_on_floor() で床の上に立っているかどうかを調べられる。立っていたら true。立ってなかったら false。
• move_and_slide() と move_and_slide_with_snap() の違いは、前者が斜め床に非対応で、後者が斜め床に対応 ―― 床に吸着して移動ができるらしい。
• move_and_slide_with_snap() は斜め床にも対応しているけれど、ジャンプしようとした時も床に吸着されてジャンプできなくなるので、ジャンプ時は吸着用(?)ベクトルを 0 にする。(Vector2.ZERO = Vector2(0, 0))

Vector2 move_and_slide_with_snap ( Vector2 velocity,
                                   Vector2 snap,
                                   Vector2 up_direction,
                                   bool stop_on_slope,
                                   int max_slides,
                                   float floor_max_angle,
                                   bool infinite_inertia )

• velocity ... 移動ベクトル。単位はピクセル/秒。1秒で何ピクセル移動するか。
• snap ... 床への吸着用ベクトル。このベクトルの範囲内に床があった場合は床に吸着されるので、斜め床に張り付いたまま動ける。
• up_direction ... 上方向を指定する。Vector2.UP (= Vector2(0, -1)) を指定。省略時はデフォルト値 Vector2(0, 0) が入る。
• stop_on_slope ... true なら、Body(?)が静止してる場合に斜面の上で滑らなくなる。デフォルトは false。
• max_slides ... 衝突してから静止するまで何回スライドするか、らしい。デフォルト値は4。
• floor_max_angle ... 床として扱う角度を指定。デフォルトは 0.785398ラジアン(45度)。BGアタリに45度の床が混ざってると床として扱われなくなるので、その場合は 45度以上を指定してやると良いらしい。ちなみに、deg2rad(度) で度をラジアンに変換できる。
• infinite_inertia ... RigidBody2D への反映を変化させるらしいが…よくわからない。