mieki256's diary

    ; hsp3dish + fullscreen test. move stars.
    ;
    ; Windows10 x64 22H2 + HSP 3.7beta7
    ; 2023/11/01 by mieki256
    ; Licence : CC0 / Public Domain
    
    #include "hsp3dish.as"
    #include "d3m.hsp"
    
    #packopt name "fullscreen_zoom"
    #packopt type 0
    
    #define TEX_FILE    "star.png"
    ; #define TEX_FILE    "star2.png"
    #pack   TEX_FILE
    
    #define KB_ESC      $000080
    #define FRAMERATE   60
    
    fps_display_enable = 1
    
    ; get desktop size
    dispw = ginfo_dispx
    disph = ginfo_dispy
    
    ; initialize window without frame
    ; bgscr WindowID, width, height, mode, x, y
    bgscr 0, dispw, disph, 0, 0, 0
    
    ; load image
    imgid = 3
    celload TEX_FILE, imgid

    ; split image. set orign
    celdiv imgid, 512, 512, 256, 256

    ; Set the buffer to draw from. Windows ID 0
    gsel 0, 1
    
    ; Set screen clear color to be performed when redraw 0 is called.
    ; 0 or 1, color ($000000 - $ffffff)
    ; setcls CLSMODE_SOLID, $4080c0
    setcls CLSMODE_SOLID, $000000
    
    font "Tahoma", 24, 1
    
    randomize
    
    star_size = 0.75
    dist = 150.0        ; screen distabce
    area_z = 5000
    zmax = double(area_z) + dist
    
    ; rnd() only accepts 1 to 32768.
    ; adjust the value to stay within that range.
    area_m = 4.0
    area_w = int((double(dispw) * zmax) / dist / area_m)
    area_h = int((double(disph) * zmax) / dist / area_m)
    
    objmax = 512
    
    ; initialize stars work
    ddim posx, objmax       ; position x
    ddim posy, objmax       ; position y
    ddim posz, objmax       ; position z
    dim px, objmax          ; display position x
    dim py, objmax          ; display position y
    ddim scalev, objmax     ; scale
    dim alpha, obj_max      ; alpha value
    repeat objmax
        gosub *get_newpos_xy
        posx(cnt) = nx
        posy(cnt) = ny
        posz(cnt) = double(rnd(area_z)) + dist
        px(cnt) = 0
        py(cnt) = 0
        scale(cnt) = 0.0
        alpha(cnt) = 0
    loop
    
    time_start = d3timer()
    endfg = 0
    
; ----------------------------------------
*mainloop
    while endfg == 0
        tm = d3timer() - time_start
        fps = d3getfps()                ; get FPS
        
        ; ESC key to exit
        stick key, 0
        if key & KB_ESC : endfg = 1
        
        ; move stars
        spd = 40.0
        repeat objmax
            posz(cnt) -= spd
            if posz(cnt) < (dist / 2.0) {
                posz(cnt) += zmax
                gosub *get_newpos_xy
                posx(cnt) = nx
                posy(cnt) = ny
            }
            
            ; get display x, y position
            px(cnt) = int(posx(cnt) * dist / posz(cnt)) + (dispw / 2)
            py(cnt) = int(posy(cnt) * dist / posz(cnt)) + (disph / 2)
            scalev(cnt) = star_size * dist / posz(cnt)
            
            size = int(512.0 * scalev(cnt))
            x0 = px(cnt) - (size / 2)
            y0 = py(cnt) - (size / 2)
            x1 = px(cnt) + (size / 2)
            y1 = py(cnt) + (size / 2)
            if x1 < 0 or x0 > dispw or y1 < 0 or y0 > disph {
                ; out of display area. position reset
                posz(cnt) += zmax
                gosub *get_newpos_xy
                posx(cnt) = nx
                posy(cnt) = ny
                px(cnt) = int(posx(cnt) * dist / posz(cnt)) + (dispw / 2)
                py(cnt) = int(posy(cnt) * dist / posz(cnt)) + (disph / 2)
                scalev(cnt) = star_size * dist / posz(cnt)
            }
            
            ; get alpha value
            az = double(area_z) * 0.7
            if posz(cnt) < az {
                alpha(cnt) = 255
            } else {
                ; fade in
                z = posz(cnt)
                if z > zmax : z = zmax
                v0 = z - az
                v1 = zmax - az
                alpha(cnt) = int(255.0 - (255.0 * v0 / v1))
            }
        loop
        
        ; ----------------------------------------
        ; draw start
        redraw 0
        
        ; clear screen
        ; color 64, 128, 192
        ; boxf
        
        ; draw stars
        repeat objmax
            rot = 0.0
            idx = 0
            
            ; draw image by celput
            gmode gmode_add, 512, 512, alpha(cnt)
            pos px(cnt), py(cnt)
            rot = 0.0
            idx = 0
            celput imgid, idx, scalev(cnt), scalev(cnt), rot
        loop

        ; draw text
        if fps_display_enable {
            gmode gmode_rgb0
            color 255, 255, 255
            pos 10, 10
            mes strf("[%dx%d] %d/%dFPS", dispw, disph, fps, FRAMERATE)
        }
        
        ; draw end. screen refersh
        redraw 1
        
        await (1000 / FRAMERATE)
        ; await 12
    wend
    
*jobend:
    end
    
*get_newpos_xy
    nx = double(rnd(area_w) - (area_w / 2)) * area_m
    ny = double(rnd(area_h) - (area_h / 2)) * area_m
    return

本作は、手塚プロアシスタント経験者らで構成された企画集団「ひろみプロ」が企画した「少女版SF変身物作品」を具体化したものである。

ミラクル少女リミットちゃん - Wikipedia より

• xfed2
• XmBDFEditor (xmbdfed)
• gbdfed

• HSP製プログラム実行時にデフォルトで作られる表示ウインドウ(ウインドウID0)には、一切手を付けない。
• ウインドウID2の表示ウインドウをフルスクリーン表示で新規に作成して、そちらに描画をしていく。

• 表示ウインドウは1つしか持てない。複数の表示ウインドウは作れない。
• プログラム実行時に作られるウインドウID0の表示ウインドウだけが、描画可能なウインドウになる。

    ; screensaver sample for hsp3dish.
    ; fork arusave.hsp
    ;
    ; This program does not work.
    ;
    ; hsp3dish を使ってスクリーンセーバが作れるか実験したが、失敗に終わった。
    ;
    ; Windows10 x64 22H2 + HSP 3.7 beta7
    ;
    ; 2023/11/04 by mieki256
    
    #include "hsp3dish.as"
    #include "d3m.hsp"
    
    ; 以下の行のコメントアウトを外すとスクリーンセーバとして実行ファイルを作成する
    ; #define SCREENSAVER_ENABLE
    
    #define TITLE_STR   "Screensaver sample for hsp3dish"
    #define VER_STR     "0.0.1"
    
    #packopt name "h3dshscr"
    
#ifdef SCREENSAVER_ENABLE
    #packopt type 2
#else
    #packopt type 0
#endif
    
    #packopt xsize  640     ; 設定画面横幅
    #packopt ysize  360     ; 設定画面縦幅

    #define TEX_FILE        "star.png"
    #define PREVIEWFILE     "preview.png"
    #pack TEX_FILE
    #pack PREVIEWFILE
    
    #define KB_ESC      $000080
    #define FRAMERATE   60
    
    fps_display_enable = 1
    
    ; ----------------------------------------
    ; parse command line option
    
    s = dir_cmdline         ; get command line option
    i = instr(s, 0, "/")    ; "/" の出現位置を検索
   
    if i = -1 {
        ; not option
#ifdef SCREENSAVER_ENABLE
        goto *config_mode
#else
        goto *fullscreen_mode
#endif
        ; goto *preview_mode
    }
    
    a = strmid(s, i, 2)     ; 2文字だけ取り出し
    
    if a == "/p" or a == "/P" : goto *preview_mode      ; プレビュー
    if a == "/s" or a == "/S" : goto *fullscreen_mode   ; フルスクリーン
    if a == "/c" or a == "/C" : goto *config_mode       ; コンフィグ
    
    ; コマンドラインがどれでもない時はエラー表示
    dialog "Unknown switch [" + s + "]"
    end

*config_mode
    ; 設定画面
    
    screen 0, 640, 360, 0
    gsel 0
    cls
    
    tt = "Config - " + TITLE_STR + " " + VER_STR
    title tt
    font "Tahoma", 24, 1
    
    redraw 0
    color 0, 0, 0
    
    pos 20, 20
    mes "Config - " + TITLE_STR
    
    pos 20, 50
    mes "Version : " + VER_STR
    
    pos 520, 300
    button "OK", *ssend
    
    redraw 1
    stop
    
*ssend
    end

*preview_mode
    ; プレビュー画面
    ; スクリーンセーバー選択時の、小さな画面内でのプレビューの処理。
    ; HSPのWindow ID0がプレビュー画面に合わせて小さくなっているので、
    ; ginfo_winx, ginfo_winy で画面サイズを取得後、その中に描画する。
    ; 経験上、単に画像を表示してstopしたほうが不具合が起きにくい。
    wdw_w = ginfo_winx
    wdw_h = ginfo_winy
    
    ; load preview image
    imgid = 3
    w = 152
    h = 112
    buffer imgid, w, h
    picload PREVIEWFILE
    iw = ginfo_winx
    ih = ginfo_winy
    
    ; draw
    gsel 0
    redraw 0
    cls 4
    gmode gmode_gdi, iw, ih
    gzoom wdw_w, wdw_h, imgid, 0, 0, iw, ih, 1
    redraw 1
    
    stop

; ----------------------------------------
*fullscreen_mode
    ; フルスクリーン描画処理
    
    ; get desktop size
    dispw = ginfo_dispx
    disph = ginfo_dispy
    
    ; initialize window without frame
    ; bgscr WindowID, width, height, mode, x, y
    bgscr 0, dispw, disph, 0, 0, 0, dispw, disph
    
    ; load image
    imgid = 3
    celload TEX_FILE, imgid

    ; split image. set orign
    celdiv imgid, 512, 512, 256, 256

    ; Set the buffer to draw from. Windows ID 0
    gsel 0, 1
    
    ; Set screen clear color to be performed when redraw 0 is called.
    ; 0 or 1, color ($000000 - $ffffff)
    ; setcls CLSMODE_SOLID, $4080c0
    setcls CLSMODE_SOLID, $000000
    
    font "Tahoma", 24, 1
    
    randomize
    
    star_size = 0.75
    dist = 150.0        ; screen distabce
    area_z = 5000
    zmax = double(area_z) + dist
    
    ; rnd() only accepts 1 to 32768.
    ; adjust the value to stay within that range.
    area_m = 4.0
    area_w = int((double(dispw) * zmax) / dist / area_m)
    area_h = int((double(disph) * zmax) / dist / area_m)
    
    objmax = 512
    
    ; initialize stars work
    ddim posx, objmax       ; position x
    ddim posy, objmax       ; position y
    ddim posz, objmax       ; position z
    dim px, objmax          ; display position x
    dim py, objmax          ; display position y
    ddim scalev, objmax     ; scale
    dim alpha, obj_max      ; alpha value
    dim patidx, obj_max     ; pattern index
    repeat objmax
        gosub *get_newpos_xy
        posx(cnt) = nx
        posy(cnt) = ny
        patidx(cnt) = idx
        posz(cnt) = double(rnd(area_z)) + dist
        px(cnt) = 0
        py(cnt) = 0
        scale(cnt) = 0.0
        alpha(cnt) = 0
    loop
    
    time_start = d3timer()
    endfg = 0
    
; ----------------------------------------
*mainloop
    while endfg == 0
        tm = d3timer() - time_start
        fps = d3getfps()                ; get FPS
        
#ifndef SCREENSAVER_ENABLE
        ; ESC key to exit
        stick key, 0
        if key & KB_ESC : endfg = 1
#endif
        
        ; move stars
        spd = 40.0
        repeat objmax
            posz(cnt) -= spd
            if posz(cnt) < (dist / 2.0) {
                posz(cnt) += zmax
                gosub *get_newpos_xy
                posx(cnt) = nx
                posy(cnt) = ny
                patidx(cnt) = idx
            }
            
            ; get display x, y position
            px(cnt) = int(posx(cnt) * dist / posz(cnt)) + (dispw / 2)
            py(cnt) = int(posy(cnt) * dist / posz(cnt)) + (disph / 2)
            scalev(cnt) = star_size * dist / posz(cnt)
            
            size = int(512.0 * scalev(cnt))
            x0 = px(cnt) - (size / 2)
            y0 = py(cnt) - (size / 2)
            x1 = px(cnt) + (size / 2)
            y1 = py(cnt) + (size / 2)
            if x1 < 0 or x0 > dispw or y1 < 0 or y0 > disph {
                ; out of display area. position reset
                posz(cnt) += zmax
                gosub *get_newpos_xy
                posx(cnt) = nx
                posy(cnt) = ny
                patidx(cnt) = idx
                px(cnt) = int(posx(cnt) * dist / posz(cnt)) + (dispw / 2)
                py(cnt) = int(posy(cnt) * dist / posz(cnt)) + (disph / 2)
                scalev(cnt) = star_size * dist / posz(cnt)
            }
            
            ; get alpha value
            az = double(area_z) * 0.7
            if posz(cnt) < az {
                alpha(cnt) = 255
            } else {
                ; fade in
                z = posz(cnt)
                if z > zmax : z = zmax
                v0 = z - az
                v1 = zmax - az
                alpha(cnt) = int(255.0 - (255.0 * v0 / v1))
            }
        loop
        
        ; ----------------------------------------
        ; draw start
        redraw 0
        
        ; clear screen
        ; color 64, 128, 192
        ; boxf
        
        ; draw stars
        repeat objmax
            rot = 0.0
            idx = 0
            
            ; draw image by celput
            gmode gmode_add, 512, 512, alpha(cnt)
            pos px(cnt), py(cnt)
            rot = 0.0
            idx = patidx(cnt)
            celput imgid, idx, scalev(cnt), scalev(cnt), rot
        loop

        ; draw text
        if fps_display_enable {
            gmode gmode_rgb0
            color 255, 255, 255
            pos 10, 10
            mes strf("[%dx%d] %d/%dFPS", dispw, disph, fps, FRAMERATE)
        }
        
        ; draw end. screen refersh
        redraw 1
        
        await (1000 / FRAMERATE)
        ; await 12
    wend
    
*jobend:
    end
    
*get_newpos_xy
    nx = double(rnd(area_w) - (area_w / 2)) * area_m
    ny = double(rnd(area_h) - (area_h / 2)) * area_m
    idx = rnd(4)
    return

    ; screensaver sample for HGIMG3. fork arusave.hsp
    ;
    ; HSP + HGIMG3を使ってスクリーンセーバを作れるか実験
    ;
    ; Windows10 x64 22H2 + HSP 3.7 beta7, 2023/11/06 by mieki256
    
    #include "hgimg3.as"
    #include "d3m.hsp"
    
    ; 以下の行をコメントアウトすればexeになる
    ;#define SCREENSAVER_ENABLE
    
    #define TITLESTR    "Screensaver for HGIMG3"
    #define VERSTR      "0.0.1"
    #packopt name       "sshgimg3"
   
#ifdef SCREENSAVER_ENABLE
    #packopt type 2         ; generate ".scr"
#else
    #packopt type 0         ; generate ".exe"
#endif
    
    #packopt xsize  640     ; 設定画面横幅
    #packopt ysize  320     ; 設定画面縦幅

    #define TEXFILE         "ball.png"
    #define PREVIEWFILE     "preview.png"
    #define FONTFILE        "font.png"
    
    #pack   TEXFILE
    #pack   PREVIEWFILE
    #pack   FONTFILE
    
    #define KB_ESC      $000080
    
    #define NWDW_ID     2
    
    ; paramater
    framerate = 60
    fps_disp_enable = 1
    
    ; ----------------------------------------
    ; コマンドラインオプションを解析
    
    s = dir_cmdline         ; コマンドラインオプション文字列を取得
    i = instr(s, 0, "/")    ; "/" の出現位置を検索
    if i == -1 {
        ; オプション無し
#ifdef SCREENSAVER_ENABLE
        goto *config_mode
#else
        goto *fullscreen_mode
#endif
        ; goto *preview_mode
    }
    
    a = strmid(s, i, 2)     ; 2文字だけ取り出し
    if a == "/p" or a == "/P" : goto *preview_mode      ; プレビュー
    if a == "/s" or a == "/S" : goto *fullscreen_mode   ; フルスクリーン
    if a == "/c" or a == "/C" : goto *config_mode       ; コンフィグ
    
    ; コマンドラインがどれでもない時はエラー表示
    dialog "Unknown switch [" + s + "]"
    end

*config_mode
    ; 設定画面モード
    goto *display_config_dialog_only
    
*preview_mode
    ; プレビュー画面モード
    goto *display_preview

; ----------------------------------------
*fullscreen_mode
    ; フルスクリーン描画処理
    
    ; デスクトップサイズを取得
    dispw = ginfo_dispx
    disph = ginfo_dispy
    
    ; ウインドウID=2で枠無しウインドウを新規作成
    ; これができないとHSPでスクリーンセーバを作れない
    ; bgscr WindowID, width, height, mode, x, y, width, height
    bgscr NWDW_ID, dispw, disph, 0, 0, 0, dispw, disph
    
    ; HGIMG3初期化
    hgini
    
    ; ビットマップフォントを設定。フォント画像を読み込み
    setfont 20, 20, 18, 1   ; 20x20 font
    texload FONTFILE
    
    ; 画像を読み込み
    texload2 TEXFILE
    texid = stat        ; get texture ID
    texw = 128
    texh = 128
    
    gsel NWDW_ID, 1
    
    clscolor $000000    ; set clear color
    
    ; clsblur 24        ; set blur. 0 - 255
    
    randomize
    
    ; ワーク初期化
    x = dispw / 2
    y = disph / 2
    dy = double(disph) / double(framerate)
    dx = dy
    
    time_start = d3timer()          ; get time
    
    endfg = 0
    
; ----------------------------------------
*mainloop
    while endfg == 0
        tm = d3timer() - time_start
        fps = d3getfps()            ; get FPS
        
#ifndef SCREENSAVER_ENABLE
        ; ESC key to exit
        stick key, 0
        if key & KB_ESC : endfg = 1
#endif
        
        ; move ball
        x += dx
        y += dy
        
        wh = texw / 2
        hh = texh / 2
        if (x - wh) < 0 or (x + wh) > dispw : dx *= -1
        if (y - hh) < 0 or (y + hh) > disph : dy *= -1
        
        ; ----------------------------------------
        ; draw start
        hgdraw
        
        ; clear screen
        ; color 64, 128, 192
        ; boxf
        
        ; draw ball
        src_w = texw
        src_h = texh
        dst_w = texw
        dst_h = texh
        rot = 0.0
        
        gmode gmode_rgb0, texw, texh
        pos x, y
        hgrotate texid, src_w, src_h, rot, dst_w, dst_h

        ; draw text
        if fps_disp_enable {
            gmode gmode_rgb0
            fprt strf("[%dx%d] %d/%dFPS", dispw, disph, fps, framerate), 10, 10
        }
        
        ; draw end. screen refersh. wait
        t = (1000 / framerate) - 1
        if t <= 0 : t = 1
        hgsync t
    wend            ; end main loop
    
*jobend:
    end
    
; ----------------------------------------
; プレビュー画面表示
; 「スクリーンセーバの変更」ウインドウ内で表示されるプレビュー処理。
; HSPのWindow ID0がプレビュー画面に合わせて小さくなっているので、
; ginfo_winx, ginfo_winy で画面サイズを取得後、その中に描画する。
;
; 経験上、単に画像を表示してstopしたほうが不具合が起きにくい。
; ここでアニメーションさせると、プログラム終了時に、
; Windowsイベントビューアにエラーが残る状態になったりする。
;
; ここではHGIMG3の描画機能を使わず、
; HSP標準の描画機能を使ってレイアウトしている。

*display_preview
    
    ; get preview window size
    wdw_w = ginfo_winx
    wdw_h = ginfo_winy
    
    ; load image
    imgid = 3
    w = 152
    h = 112
    buffer imgid, w, h      ; reserve image buffer
    picload PREVIEWFILE     ; load image file
    iw = ginfo_winx         ; get image size
    ih = ginfo_winy
    
    ; draw
    gsel 0
    redraw 0    ; draw start
    cls 4
    
    ; 画像をウインドウ全体に引き延ばして描画
    gmode gmode_gdi, iw, ih
    gzoom wdw_w, wdw_h, imgid, 0, 0, iw, ih, 1
    
    redraw 1    ; draw end. Refresh
    
    stop

; ----------------------------------------
; 設定画面を描画
; 本来は動作パラメータを設定できるウインドウになるはず。
; 今回は、プログラム名、バージョン、終了のためのOKボタンを表示しかしない。
;
; ここではHGIMG3の描画機能を使わず、
; HSP標準の描画機能を使ってレイアウトしている。

*display_config_dialog_only
    
    screen 0, 640, 320, 0           ; Reset window ID=0
    
    title TITLESTR + " " + VERSTR   ; set window title
    
    gsel 0, 1                       ; select window
    cls                             ; clear window
    font "Tahoma", 18, 1            ; set font kind, font size, bold
    
    redraw 0                        ; draw start
    
    gmode gmode_rgb0
    color 0, 0, 0
    pos 20, 20
    mes "Config - " + TITLESTR
    pos 20, 50
    mes "Version : " + VERSTR
    
    pos 520, 260
    button "OK", *config_end
    
    redraw 1                        ; draw end. refresh
    
    await 15
    stop
    
*config_end
    end

1. 小さいイメージバッファ(ID=1)を新規作成
2. その小さいイメージバッファ(ID=1)に HGIMG4 (hsp3dish) を使って描画
3. そのイメージバッファの内容をメインの表示ウインドウ(ID=0)に拡大描画

• 複数の表示ウインドウを持てるけど、描画先は1つのウインドウに限られてしまう HGIMG3。
• 複数のイメージバッファに描画できるけど、表示ウインドウは1つに限定されてしまう HGIMG4 (hsp3dish)。

    ; hgcapture使用サンプルその2
    ; 表示ウインドウを2つ新規作成して、片方を仮想画面相当、片方をメイン表示にする
    
    #include "hgimg3.as"
    #include "d3m.hsp"
    
    ; 以下の行をコメントアウトするとウインドウ表示になる
    ;#define FULLSCR
    
    #packopt name   "07_hgcapture_02"   ; file name
    #packopt type   0                   ; generate ".exe"

    #define TEXFILE     "chara.png"
    #pack   TEXFILE
    
    #define KB_ESC  128
    #define KB_LEFT     $00001
    #define KB_UP       $00002
    #define KB_RIGHT    $00004
    #define KB_DOWN     $00008
    #define KB_CURSOR   (KB_LEFT | KB_UP | KB_RIGHT | KB_DOWN)
    
    framerate = 60
    
    title "Screen 0"
    
    ; メイン表示ウインドウを確保。HSPの標準描画機能で描画していく
    dispid = 2
    
#ifdef FULLSCR
    ; get desktop size
    dispw = ginfo_dispx
    disph = ginfo_dispy
    bgscr dispid, dispw, disph, 0, 0, 0, dispw, disph
#else
    dispw = 1280
    disph = 720
    screen dispid, dispw, disph, 0
    title "Screen " + dispid
#endif
    
    ; hgcapture用バッファを確保
    tbufid = 6
    vscrw = 512
    vscrh = 288
    buffer tbufid, vscrw, vscrh
    
    ; 仮想画面相当の表示ウインドウを確保。HGIMG3で描画していく
    vscrid = 5
    ; modevalue = screen_hide
    modevalue = 0
    screen vscrid, vscrw, vscrh, modevalue
    title "Screen " + vscrid
    
    hgini
    
    ; load texture
    texload2 TEXFILE
    texid = stat            ; get texture ID
    texw = 16
    texh = 16
    
    clscolor $4080c0        ; set clear color
    
    count = 0
    x = (vscrw / 2)
    y = (vscrh / 2)
    
    time_start = d3timer()
    
*mainloop
    repeat
        ; get FPS
        tm = d3timer() - time_start
        fps = d3getfps()
        
        ; ESC key to exit
        stick k, KB_CURSOR
        if k & KB_ESC : break
        
        ; move character
        spd = 3
        if k & KB_LEFT : x -= spd
        if k & KB_RIGHT : x += spd
        if k & KB_UP : y -= spd
        if k & KB_DOWN : y += spd
        
        hgdraw
        
        ; draw images (HGIMG3)
        gmode gmode_rgb0, texw, texh
        pos x, y
        src_x = ((count / 16) \ 2) * texw
        src_y = 0
        rot = 0.0
        scale = 3
        dst_w = texw * scale
        dst_h = texh * scale
        hgrotate texid, src_x, src_y, rot, dst_w, dst_h

        ; HGIMG3 の描画結果をキャプチャしてbuffer(ID=tbufid)にコピー
        ; 右端と下端に数ドット黒部分が出るのはバグらしい
        gsel tbufid
        hgcapture
        
        ; メイン表示ウインドウにHGIMG3の描画結果を描画していく
        gsel dispid
        redraw 0
        
        ; zoom copy tbufid -> dispid (HSP標準描画機能)
        if 1 {
            gmode gmode_gdi
            pos 0, 0
            gzoom dispw, disph, tbufid, 0, 0, vscrw, vscrh, 1
        } else {
            gmode gmode_gdi, vscrw, vscrh
            pos (dispw / 2), (disph / 2)
            grotate tbufid, 0, 0, 0.0, dispw, disph
        }
        
        ; draw text (HSP標準描画機能)
        if 1 {
            font "Tahoma", 20, 1, 2
            objcolor 255, 255, 255
            color 16, 16, 16
            pos 16, 16
            mes strf("[%dx%d] %d FPS", vscrw, vscrh, fps), 4
        }
        
        redraw 1
        
        t = (1000 / framerate) - 1
        if t <= 0 : t = 1
        hgsync t
        
        count++
    loop
    
*mainloop_end
    end

    ; hgcapture使用サンプル
    
    #include "hgimg3.as"
    #include "d3m.hsp"
    
    ; 以下の行をコメントアウトするとウインドウ表示になる
    #define FULLSCR
    
    #packopt name   "07_hgcapture"  ; file name
    #packopt type   0               ; generate ".exe"
    
    #define TEXFILE     "tex.png"
    #pack   TEXFILE
    
    #define KB_ESC  128
    
    framerate = 60
    
    title "Screen 0"
    
    ; メイン表示ウインドウを確保
    dispid = 2
    
#ifdef FULLSCR
    ; get desktop size
    dispw = ginfo_dispx
    disph = ginfo_dispy
    bgscr dispid, dispw, disph, 0, 0, 0, dispw, disph
#else
    dispw = 1600
    disph = 900
    screen dispid, dispw, disph, 0
    title "Screen " + dispid
#endif

    ; hgcapture用バッファを確保
    vscrw = 800
    vscrh = 450
    tbufid = 6
    buffer tbufid, vscrw, vscrh
    
    ; 仮想画面相当の表示ウインドウを確保
    vscrid = 5
    ;modevalue = screen_hide
    modevalue = 0
    screen vscrid, vscrw, vscrh, modevalue
    title "Screen " + vscrid
    
    hgini
    
    ; load texture
    texload2 TEXFILE
    texid = stat            ; get texture ID
    texw = 512
    texh = 512
    
    clscolor $4080c0        ; set clear color
    
    angle = 0.0
    
    time_start = d3timer()
    
*mainloop
    repeat
        ; get FPS
        tm = d3timer() - time_start
        fps = d3getfps()
        
        ; ESC key to exit
        stick k, 0
        if k & KB_ESC : break
        
        angle += 0.5
        
        hgdraw
        
        ; draw images (HGIMG3)
        objmax = 96
        repeat objmax
            r = double(vscrh) * 0.5
            a = angle + (270.0 / double(objmax)) * double(cnt)
            x = int(r * cos(deg2rad(a))) + (vscrw / 2)
            y = int(r * sin(deg2rad(a))) + (vscrh / 2)
            d = double(cnt) / double(objmax)
            
            src_x = (idx \ 2) * texw
            src_y = ((idx / 2) \2) * texh
            idx = (cnt \ 4)
            rot = deg2rad(angle * 2.0 + 360.0 * d)
            ; scale = 1.0 - (0.75 * d)
            scale = 2.0 - (1.75 * d)
            dst_w = int(double(texw) * scale)
            dst_h = int(double(texh) * scale)
            
            ; draw image by celput
            gmode gmode_rgb0, texw, texh
            pos x, y
            hgrotate texid, src_x, src_y, rot, dst_w, dst_h
        loop
        
        if 0 {
            t = (1000 / framerate) - 1
            if t <= 0 : t = 1
            hgsync t
        } else {
            hgsync 12
        }
            
        ; HGIMG3 の描画結果をキャプチャしてbuffer(ID=tbufid)にコピー
        ; 右端と下端に数ドット黒部分が出るのはバグらしい
        gsel tbufid
        ; redraw 0
        hgcapture
        ; redraw 1
       
        ; メイン表示ウインドウにHGIMG3の描画結果を描画していく
        gsel dispid
        redraw 0
        
        ; tbufid から dispid に拡大描画 (HSP標準描画機能)
        if 1 {
            gmode gmode_gdi
            pos 0, 0
            gzoom dispw, disph, tbufid, 0, 0, vscrw, vscrh, 0
        } else {
            gmode gmode_gdi, vscrw, vscrh
            pos (dispw / 2), (disph / 2)
            grotate tbufid, 0, 0, 0.0, dispw, disph
        }
        
        ; draw text (HSP標準描画機能)
        if 1 {
            font "Tahoma", 20, 1, 2
            objcolor 255, 255, 255
            color 16, 16, 16
            pos 16, 16
            mes strf("[%dx%d] %d FPS", vscrw, vscrh, fps), 4
        }
        
        redraw 1
        
        await (1000 / framerate)
    loop
    
*mainloop_end
    end

sudo apt update
sudo apt upgrade
sudo add-apt-repository ppa:tomtomtom/woeusb
sudo apt update
sudo apt install woeusb woeusb-frontend-wxgtk

woeusbgui

bootrec /fixmbr
bootrec /fixboot
bootrec /rebuildbcd 

REG ADD HKLM\SYSTEM\CurrentControlSet\Control\SafeBoot\Network\MSIServer /ve /d Service
REG ADD HKLM\SYSTEM\CurrentControlSet\Control\SafeBoot\Network\wuauserv /ve /d Service
REG ADD HKLM\SYSTEM\CurrentControlSet\Control\SafeBoot\Network\BITS /ve /d Service
REG ADD HKLM\SYSTEM\CurrentControlSet\Control\SafeBoot\Network\EventSystem /ve /d Service
REG ADD HKLM\SYSTEM\CurrentControlSet\Control\SafeBoot\Network\UsoSvc /ve /d Service
REG ADD HKLM\SYSTEM\CurrentControlSet\Control\SafeBoot\Network\DoSvc /ve /d Service

REG DELETE HKLM\SYSTEM\CurrentControlSet\Control\SafeBoot\Network\MSIServer /f
REG DELETE HKLM\SYSTEM\CurrentControlSet\Control\SafeBoot\Network\wuauserv /f
REG DELETE HKLM\SYSTEM\CurrentControlSet\Control\SafeBoot\Network\BITS /f
REG DELETE HKLM\SYSTEM\CurrentControlSet\Control\SafeBoot\Network\EventSystem /f
REG DELETE HKLM\SYSTEM\CurrentControlSet\Control\SafeBoot\Network\UsoSvc /f
REG DELETE HKLM\SYSTEM\CurrentControlSet\Control\SafeBoot\Network\DoSvc /f

• ImgDrive 2.0.6 : isoを仮想ドライブにマウントできるツール。2.0.6 をアンインストールした直後に 2.1.2 を再インストール。
• ORAKUIN : キー入力・マウス操作を画面上で視覚化してくれるツール
• ELECOMらくちんプリント3.0 : ラベル印刷用ソフト。OSのstartup時に何かしてるので…。
• SVG See 1.1.0 ... エクスプローラ上でSVGのサムネイル表示をしてくれるツール。PowerToysが同機能を持ったので、こちらは開発停止状態になってる。
• Defraggler 2.22 : デフラグソフト
• UltraDefrag (Ultra Defragmenter) 7.1.4 : デフラグソフト
• iTunes : Apple のアレ。

HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Class\{4d36e965-e325-11ce-bfc1-08002be10318}
HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Control\Class\{4D36E965-E325-11CE-BFC1-08002BE10318}

HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\PxHlpa64

デバイスに問題が発生したため、再起動する必要があります。再起動できます。

停止コード : INACCESSIBLE_BOOT_DEVICE

dir G:\Windows\System32
dir D:\home\AppliData\sysbkup\sptd2_sys_bkup\2.13.0.0
copy D:\home\AppliData\sysbkup\sptd2_sys_bkup\2.13.0.0\sptd2.sys G:\Windows\System32\drivers

HKEY_LOCAL_MACHINE\System\CurrentControlSet\Services\sptd
HKEY_LOCAL_MACHINE\System\CurrentControlSet\Services\sptd2

1. コマンドプロンプト上で regedit と打って、レジストリエディタを起動。
2. HKEY_LOCAL_MACHINE を選択した状態で、ファイル → ハイブの読み込み、を選択。
3. G:\Windows\System32\config\SYSTEM というファイル(レジストリファイル)を選択。
4. マウントキー名の入力を求められるので temp と打った。
5. HKEY_LOCAL_MACHINE\temp 以下に、G:\Windows\System32\config\SYSTEM の内容が読み込まれた。

bootrec /FixMbr
bootrec /FixBoot
bootrec /RebuildBcd

sudo apt install qt5ct

export QT_QPA_PLATFORMTHEME="qt5ct"
export GTK2_RC_FILES="$HOME/.gtkrc-2.0"

さらに、こちら(192.168.0.8)から、インターネット上のサーバーに送信しているTCPパケットの IPヘッダ中の TTL(Time to live)の値を確認したところ 3 になっていた。Windowsの Time to live の値は、デフォルトでは 128 である。

そのため、インターネットアクセスできなくなった直接の原因は、PowerDVDが、Windowsが、TCPアクセス時に使用する TTL(Time to live) の値を変更してしまったためであると思われる。

PowerDVD 17 Ultra の使い方−DTCP-IP対応DLNAクライアント機能− | ホームネットワーク構築方法 より

(2) コマンドプロンプトが管理者モードで起動する。
(3) 以下のコマンドを実行。
netsh int ipv4 set glob defaultcurhoplimit=129
netsh int ipv6 set glob defaultcurhoplimit=129

PowerDVD 17 Ultra の使い方−DTCP-IP対応DLNAクライアント機能− | ホームネットワーク構築方法 より

1. ヘルプ → トラブルシューティング情報 → プロファイルフォルダー → フォルダーを開く。
2. Thunderbirdを終了。
3. 3回上位階層に移動。
4. Thunderbirdフォルダをコピーしてバックアップ。

1. ヘルプ → 他のトラブルシューティング情報 → プロファイルフォルダー → フォルダーを開く。
2. Firefoxを終了。
3. 1回(2回？)、上位階層に移動。
4. Profileフォルダをコピーしてバックアップ。

• 馬車、風車、塔のてっぺん等、CGで作られてるように見えた。CGの出力結果を手描きでなぞってる可能性もありそうだけど…。
• 群衆はトゥーンレンダリングのCGキャラだった。
• キャラにつけてある影の輪郭線が全カットぼかしてあった。

    ; hgimg3 hgrotate bug
    ; hgrotateで奇数サイズを指定しても偶数サイズにされてしまうバグの動作確認
    ; 16x16ドットの画像を、14x16, 15x16, 16x16, ... 21x16 で描画してみた
    ; たしかに、奇数サイズは偶数サイズになってしまった
    ; 2023/11/27, use HSP 3.7 beta 7
    
    #include "hgimg3.as"
    
    #packopt name   "10_hgrotate_bug2"  ; file name
    #packopt type   0   ; generate ".exe"
    
    #define TEXFILE     "tex.png"
    #pack   TEXFILE
    
    #define KB_ESC      $00080
    
    screen 0, 512, 288, 0       ; initialize screen
    wdw_w = ginfo_winx          ; get window size
    wdw_h = ginfo_winy
    hgini                       ; initialize hgimg3
    
    ; load texture
    ; * texload : alpha channel not support
    ; * texload2 : alpha channel support
    texload2 TEXFILE
    texid = stat            ; get texture ID
    
    clscolor $4080c0        ; set clear color
    
*mainloop
    stick k, 0                      ; check keyboard
    if k & KB_ESC : goto *job_end   ; ESC key to exit
    
    hgdraw          ; draw start
    
    repeat 8
        ; draw image
        
        ; set src size 16x16
        gmode gmode_rgb0, 16, 16
        
        ; set position
        x = wdw_w / 2
        y = 80 + (16 + 4) * cnt
        pos x, y
        
        src_x = 0
        src_y = 0
        rot = 0.0
        dst_w = 14 + cnt
        dst_h = 16
        hgrotate texid, src_x, src_y, rot, dst_w, dst_h   ; draw texture
    loop
    
    hgsync 15       ; draw end and wait
    goto *mainloop

*job_end
    hgbye       ; release HGIMG3 plugin
    end

    ; hgimg3 hgrect bug
    ; 2023/11/27
    ; hgrectで奇数サイズを指定しても偶数サイズにされてしまうバグについて動作確認
    ; 14x16, 15x16, 16x16, ... 21x16 で描画してみる。
    
    #include "hgimg3.as"
    
    #packopt name   "12_hgrect_bug"  ; file name
    #packopt type   0   ; generate ".exe"
    
    #define KB_ESC      $00080
    
    screen 0, 512, 288, 0       ; initialize screen
    wdw_w = ginfo_winx          ; get window size
    wdw_h = ginfo_winy
    hgini                       ; initialize hgimg3
    
    clscolor $4080c0        ; set clear color
    
*mainloop
    stick k, 0                      ; check keyboard
    if k & KB_ESC : goto *job_end   ; ESC key to exit
    
    hgdraw          ; draw start
    
    repeat 8
        gmode 0
        color 1, 1, 1
        
        ; draw rectangle
        x = wdw_w / 2
        y = 80 + (16 + 1) * cnt
        rot = 0.0
        dst_w = 14 + cnt
        dst_h = 16
        hgrect x, y, rot, dst_w, dst_h
    loop
    
    hgsync 15       ; draw end and wait
    goto *mainloop

*job_end
    hgbye       ; release HGIMG3 plugin
    end

    ; hgimg3 hgline bug sample
    ; hglineで奇数サイズを指定した場合も偶数サイズにされるかどうか動作確認
    ; 2023/11/27, use HSP 3.7 beta 7
    
    #include "hgimg3.as"
    
    #packopt name   "13_hgline_bug"  ; file name
    #packopt type   0   ; generate ".exe"
    
    #define KB_ESC      $00080
    
    screen 0, 512, 288, 0       ; initialize screen
    wdw_w = ginfo_winx          ; get window size
    wdw_h = ginfo_winy
    hgini                       ; initialize hgimg3
    
    clscolor $4080c0        ; set clear color
    
*mainloop
    stick k, 0                      ; check keyboard
    if k & KB_ESC : goto *job_end   ; ESC key to exit
    
    hgdraw          ; draw start
    
    gmode 0
    color 128, 128, 128
    hgrect 8, 8, 0.0, 16, 16
    
    repeat 8
        gmode 0
        color 1, 1, 1
        
        ; draw rectangle
        x = 0
        y = 0 + (2 * cnt)
        w = cnt
        hgline x + w, y, x, y
    loop
    
    hgsync 15       ; draw end and wait
    goto *mainloop

*job_end
    hgbye       ; release HGIMG3 plugin
    end

llmod3,HGIMG/HGIMGX,HSPDXのプラグイン・モジュールは非推奨となっています

HSP3.5 アップデートガイド より

5. パッケージの同梱終了について

(中略) また、以下のプラグイン・モジュールは、非推奨として扱われているため、マニュアル及びヘルプは、提供されません。

* llmod3 -> HSP3に対応した各種モジュールをご使用ください
* HGIMG / HGIMGX (3D描画用プラグイン) -> HGIMG3/HGIMG4をご使用ください
* HSPDX (2D描画用プラグイン) -> HSP3DISHをご使用ください

これらのプラグイン・モジュールは、コードが古くなっており、現行のWindows上での動作が保証されません。既存コードのコンパイル及び実行はサポートされますが、将来のバージョンでは対応されない可能性があります。

HSP3.5 アップデートガイド より

4. パッケージの同梱終了について

これまでのフルセットに同梱されていたllmod3、HGIMG / HGIMGX (3D描画用プラグイン)/HSP3MT(ランタイム)/HSPLetパッケージは、同梱されません。 古いパッケージに含まれているランタイムを引き続き使用することは可能ですが、非推奨として扱われているため、マニュアル及びヘルプは、提供されません。

* llmod3 -> HSP3に対応した各種モジュールをご使用ください
* HGIMG / HGIMGX (3D描画用プラグイン) -> HGIMG3/HGIMG4をご使用ください
* HSPDX (2D描画用プラグイン) -> HSP3DISHをご使用ください
* HSP3MTランタイム -> hsp3utfやhsp3_64をご使用ください
* HSPLetランタイム -> HSP3Dish(html5)をご使用ください

これらのプラグイン・モジュールは、コードが古くなっており、現行のWindows上での動作が保証されません。 既存コードのコンパイル及び実行はサポートされますが、将来のバージョンでは対応されない可能性があります。

HSPDXプラグインは、古くからの利用者も多く現在のシステムでも実行可能なため、プラグインファイル自体は同梱されていますが、新規で使用することは推奨されません。

HSP3 アップデートガイド より

このモードを使用することにより、デバッグをよりスムーズに行うことができますが、フルスクリーンモードでの動作に比べていろいろと制約があり、環境によってはパフォーマンス面で HSPの標準ウィンドウでの動作とほとんど変わらないことがあるため、デバッグ専用のモードだと割り切って使用した方がよいでしょう。

    ; HSPDX es_excopy sample 2
    ; ウインドウモードをフルスクリーンモードのように見せかける
    ; Window ID=2 を描画対象にしている
    ;
    ; 2023/11/29, use HSP 3.7 beta 7, Windows10 x64 22H2
    
    #include "hspdx.as"
    
    #packopt name   "01_hspdx_es_excopy2"   ; file name
    #packopt type   0       ; generate ".exe"
    
    #define TEXFILE     "tex.bmp"
    #pack   TEXFILE
    
    #define KB_ESC      $00080
    
    ; 以下の行をコメントアウトするとウインドウモードになる
    #define FULLSCR
    
    ; hspdx.dllが存在するか確認
    exist "hspdx.dll"
    if strsize < 0 {
        dialog "Not found hspdx.dll"
        end
    }
    
#ifdef FULLSCR
    ; get desktop size
    wdw_w = ginfo_dispx
    wdw_h = ginfo_dispy
    ; scmode = 0              ; set fullscreen
    scmode = 1              ; set window mode
    use_d3d = 1
#else
    ; wdw_w = 512
    ; wdw_h = 288
    wdw_w = 1600
    wdw_h = 900
    scmode = 1              ; set window mode
    use_d3d = 1
#endif

    ; 最初に作られる Window ID=0 を非表示にする
    gsel 0, -1
    
    actid = 2   ; Window ID=2 を表示ウインドウにする
    
#ifdef FULLSCR
    ; フルスクリーン相当。枠無しウインドウを作成
    bgscr actid, wdw_w, wdw_h, 0, 0, 0, wdw_w, wdw_h
#else
    ; ウインドウモード。通常のウインドウを作成
    screen actid, wdw_w, wdw_h, 0, 20, 20, wdw_w, wdw_h
#endif
    
    es_ini              ; initialize HSPDX
    onexit *job_end
    
    es_screen wdw_w, wdw_h, 32, 0, scmode, use_d3d
    if stat == 1 {
        dialog "Error : DirectX initialization failed."
        end
    }
    if stat == 2 {
        dialog "Error : Screen initialization failed."
        end
    }
    
*start
    ; load texture image file
    buffer 5, 256, 256
    picload TEXFILE
    
    texid = 0
    es_buffer texid, 0  ; copy buffer to VRAM
    if stat {
        es_bye
        wait 100
        dialog "Error : Not enough VRAM."
        end
    }
    
    gsel actid, 1           ; Activate window
    es_cls                  ; screen clear
    es_sync (1000/60), 1    ; wait
    wait 100
    
    font "Tahoma", 16, 1
    
    tt = 0
    k = 0
    x = double(wdw_w / 2)
    dx = double(wdw_w) / double(60 * 3)
    now_fps = 0
    
*mainloop
    ; get fps
    es_getfps now_fps
    ; title strf("%d/50 FPS", now_fps)
    
    stick k, 0                      ; chekc keyboard
    if k & KB_ESC : goto *job_end   ; ESC key to exit
    
    x += dx
    if x <= 0.0 or (x + 16.0) >= wdw_w {
        ; flip direction
        dx *= -1
    }
    
    ; draw start
    gsel actid
    es_cls $40, $80, $c0        ; screen clear
    
    ; draw image
    gmode gmode_rgb0, 16, 16
    pos int(x), 10
    es_copy texid, 0, 0, 16, 16
    ; es_excopy texid, 0, 0, 16, 16, 64, 64
    
    repeat 8
        ; draw image
        px = 0
        py = 40 + (16 + 2) * cnt
        sx = 0      ; source x, y
        sy = 0
        sw = 16     ; source width, height
        sh = 16
        dw = 14 + cnt   ; dest width, height
        dh = 16
        gmode gmode_rgb0, sw, sh
        objsize dw, dh
        pos px, py
        
        ; es_zoom texid, sx, sy, sw, sh, dw, dh
        es_excopy texid, sx, sy, sw, sh, dw, dh
        
        ; box fill
        px = px + dw + 2
        gmode 0, sw, sh
        color 32, 32, 32
        pos px, py
        es_boxf px, py, px + dw - 1, py + dh - 1
    loop
    
    pos (wdw_w / 2) - (16 * 4), 0
    color 255, 255, 255
    es_fmes strf("%d/60FPS", now_fps)
    
    es_sync (1000/60), 1    ; draw and wait
    tt = stat
    await 1
    goto *mainloop

*job_end
    es_bye
    end

• hspdx.dll を .exe (あるいは .scr) と同じ場所にコピーしてもらわないといけない。
• MSVCR71.DLL を、もしかすると Windows のシステムフォルダにコピーしてもらうことになるかもしれない。

1. 図形と、対称線になる線分を作っておく。
2. 図形をクリックして選択してから、対称線を Shift + クリックして、複数選択。
3. エクステンション → パスの変形 → Mirror、を選択。

1. Install Packages を選択。
2. 検索入力欄に単語を入力。「guide」と打ち込んで Enterキー。
3. 「Guide Creation Tools」がリストアップされたので、クリックして選択。
4. 「Install Package」ボタンをクリック。

• HSP起動時に作られるウインドウID0には一切手を触れない。
• 表示ウインドウID2を新規作成して、そのウインドウID2に描画していく。

; 多重起動禁止テストその2
;
; 二重起動の防止（１） - Advanced HSP
; http://chokuto.ifdef.jp/advanced/singleton1.html    
;
; 2023/11/30, Windows10 x64 22H2 + HSP 3.7 beta 7

#packopt name "test_createmutex_b"  ; filename
#packopt type 0     ; generate ".exe"

; 多重起動をチェックするためのミューテックスオブジェクト名を定義。
; アプリ固有の名前であること。
#define MUTEX_NAME  "HSP_WinAPI_Test_Mutex"

; ----------------------------------------
; アプリケーションの起動チェックを行うモジュール
#module

#uselib "kernel32.dll"
#cfunc CreateMutex  "CreateMutexA" int, int, sptr
#cfunc GetLastError "GetLastError"
#func  CloseHandle  "CloseHandle"  int

#define ERROR_ALREADY_EXISTS    183

; アプリがすでに起動されているか取得する関数
#defcfunc AlreadyAppRunning str name
    if (hMutex == 0) {
        ; 名前付きミューテックスオブジェクトの作成
        hMutex = CreateMutex(0, 0, name)

        ; オブジェクトがすでに作成されていたかどうかの判別
        if (GetLastError() == ERROR_ALREADY_EXISTS) {
            ; すでに同じ名前のオブジェクトが存在する
            alreadyRunning = 1
        } else {
            ; オブジェクトが新しく作成された
            alreadyRunning = 0
        }
    }
    return alreadyRunning

; クリーンアップ処理（終了時に自動実行）
#deffunc CleanupAppRunChecker onexit
    if (hMutex != 0) {
        ; ミューテックスオブジェクトハンドルのクローズ
        CloseHandle hMutex
        hMutex = 0
    }
    return

; ----------------------------------------
#global

*start
    if (AlreadyAppRunning(MUTEX_NAME)) {
        dialog "すでに起動されています。"
        end
    }

    mes "二重起動してしません。"
    stop