mieki256's diary

wol.exe 192.168.1.255 00-1F-D0-CF-6C-96

MagicPacket.exe 00-1F-D0-CF-6C-96 192.168.1.255

wol -i 192.168.1.255 00:1F:D0:CF:6C:96

MagicPacket.exe 001FD0CF6C96
MagicPacket.exe 00-1F-D0-CF-6C-96
MagicPacket.exe 00:1F:D0:CF:6C:96
MagicPacket.exe 001fd0cf6c96
MagicPacket.exe 00-1f-d0-cf-6c-96
MagicPacket.exe 00:1f:d0:cf:6c:96

' PT1機にMagic Packetを送信してからTVTestを起動する

Option Explicit

' Const wol_exec = "MagicSend\MagicSend.exe 00-25-22-18-9E-51"
Const wol_exec = "wwol\wol.exe 192.168.1.255 00-25-22-18-9E-51"

Const hostip = "192.168.1.28"
Const tvtest = "TVTest.exe"

Dim wsh
Set wsh = WScript.CreateObject("WScript.Shell")

Dim res
If fncPing(hostip) = False Then
    if MsgBox("チューナー機は起動していません。" & vbCr & "起動しますか？", _
              vbYesNo + vbQuestion) = vbYes then
        wsh.Run wol_exec, 2, True
        res = wsh.Popup("チューナー機を起動しました。" _
                        & vbCr & "5秒ほどお待ちください。", 4)
        If res = vbOK Then
            WScript.Sleep(5000)
        End If
    end If
Else
    res = wsh.Popup("チューナー機は既に起動しています。", 2)
End If

If fncPing(hostip) = False Then
    res = wsh.Popup("チューナー機が起動できませんでした。" _
                    & vbCr & "スクリプトを終了します。", 3)
    Set wsh = Nothing
    WScript.quit
End If

If MsgBox("TVTest を起動しますか？", vbYesNo + vbQuestion) = vbYes Then
    wsh.Run tvtest, , False
End If

Set wsh = Nothing
WScript.quit

' ping送信をする関数。
' 以下のページ内容をそのまま使わせてもらいました。
' Systemメモメモ: VBScriptでPing
' http://happy44s.blogspot.jp/2012/03/vbscriptping.html
Function fncPing(host)
Dim objWMI
Dim colItems
Dim objItem
Set objWMI = GetObject("winmgmts:\\.\root\cimv2")
Set colItems = objWMI.ExecQuery("select * from Win32_PingStatus where address ='" _
                                & host & "'")
For Each objItem In colItems
    If objItem.StatusCode = 0 Then
        fncPing = True
    Else
        fncPing = False
    End If
Next
Set objItem = Nothing
Set colItems = Nothing
Set objWMI = Nothing
End Function