mieki256's diary

vagrant + VirtualBox のようなことを VMware Player でもできないかな、せめてバックグラウンドで画面を出さずに VMware Player を起動できないか、と思ったのだけど。

ググってみたら、どうやら VMware VIX なるものを導入すると、バッチファイル等からそういうことができるらしいと知ったので、試しに触ってみたり。

_ダウンロード VMware Player 6.0 から、VMware-VIX-1.13.3-1895310.exe をDL。実行してインストール。

C:\Program Files (x86)\VMware\VMware VIX\ フォルダ内に vmrun.exe というツールがあるので、ソレを呼び出せばいいらしい。とりあえず以下のページを参考にしてバッチファイルを書いた。

_VMware PlayerをGUI無しで起動する(VIX) - Qiita
_VMPlayerのvmxをバックグラウンドで起動 - m_shige1979のささやかな抵抗と欲望の日々
_仮想サーバのCUI起動 - 気になったことをいろいろやってみる
_みかんの備忘録

vm.bat

@echo off
set DIR_VMRUN="C:\Program Files (x86)\VMware\VMware VIX"
set CMD_VMRUN=vmrun
set VMX_TARGET="vmxファイルのパスをここに書く"
cd /d %DIR_VMRUN%
if "%1"=="start" goto VMSTART
if "%1"=="suspend" goto VMSUSPEND
if "%1"=="stop" goto VMSTOP
if "%1"=="list" goto VMLIST
goto HELPMES

:HELPMES
echo VMware Player Control (for VMware VIX)
echo vm [start^|stop^|suspend^|list]
goto END

:VMSTART
start %CMD_VMRUN% -T player start %VMX_TARGET% nogui
@rem start %CMD_VMRUN% -T player start %VMX_TARGET% gui
goto END

:VMSUSPEND
start %CMD_VMRUN% -T player suspend %VMX_TARGET%
goto END

:VMSTOP
start %CMD_VMRUN% -T player stop %VMX_TARGET%
goto END

:VMLIST
%CMD_VMRUN% -T player list
echo.
echo Push Any Key
pause > NUL
goto END

:END

VMX_TARGET に、既にセットアップ済みの仮想PC(VMware)の、.vmx のパスを定義しておく。

vm start で起動。vm stop でシャットダウン。vm list で現在実行中の VMware Player の数を表示。みたいな感じ。

◎ Lubuntuをインストール。 :

◎ tsoなる設定項目があるらしい。 :