import processing.pdf.*;

/*
 時計盤を描画するProcessingスクリプト.
 ついでにストップウォッチ機能も書いてみた.
 
 by mieki256
 ver. 0.0.5 2012/01/31
 - FPSがおかしくなる不具合への対策。
 - System.nanoTime()を使って測定するよう変更。
 - 記録のファイル書き出しがバグってたので修正。
 ver. 0.0.4 2012/01/30
 - 時間をミリ秒で取得するように変更。
 - 24/30コマを切り替える機能を追加。(@キー押し)
 - 表示用フレームレート変更機能を追加。(Pキー押し)
 ver. 0.0.3 2012/01/29
 - 時計盤を事前に描画して高速化。
 - ウインドウサイズを小さくして高速化。
 ver. 0.0.2 2012/01/26
 - LAP機能を追加。
 ver. 0.0.1 2012/01/25
 - とりあえず作成。
 */

String verinfo = "Ver. 0.0.5";

// pdf出力の設定
// 0ならストップウォッチとして動く。
// 1にするとpdf出力して終了。
int pdf_out = 0;

// pdf出力ファイル名
String pdf_name = "watch_base.pdf";

// フレームレート (24か30を指定可能)
int fpsv = 24;

// 表示用フレームレート
int[] frate_list = {
  24, 30, 48, 60
};
int frate_idx = 0;
int disp_fps;

// 記録保存用テキストファイル名
String log_filename = "_log.txt";

// 0なら用意済みのフォントデータを利用
// 1ならフォントデータ生成
int create_font_use = 1;

// 使用フォント名
String[] font_name = {
  "Times New Roman Bold", 
  "Times New Roman Bold",
};

// フォントデータを事前準備してある場合のフォントファイル名
String[] font_file = {
  "DejaVuSerifCondensed-Bold-32.vlw", 
  "mplus-1m-medium-14.vlw",
};

// フォントサイズ
int[] fsize = {
  32, 
  14,
};

// 0以外なら、環境で使えるフォント一覧を出力
int font_list_out = 0;

// 0なら記録を描画しない(処理速度が遅い時は0にする)
int lap_draw = 1;

long[] lap = new long[1000]; // 時間記録用
int lapidx = 0;

int frm = 0;              // フレーム数記録用
boolean watching = false; // trueならカウントする
int req = 0;
String msg = "";
int msg_disp_cnt = 0;
PGraphics pg;
long starttime = 0;
long totaltime = 0;
boolean irq = false;

// フォントの使用
PFont[] fnt;

// ----------------------------------------
// 初期化処理
void setup() {
  // 画像サイズ指定
  // 記録表示領域の幅は190ドット必要
  size(510, 320, JAVA2D);
  // size(670, 480);
  // size(790, 600);

  // 使えるフォント一覧を出力
  if (font_list_out != 0) {
    String[] fontList = PFont.list();
    println(fontList);
  }

  // フォントのロード
  fnt = new PFont[font_name.length];
  if (create_font_use != 0) {
    // 起動時に使用フォントデータを作成する例
    for ( int i=0; i<font_name.length; i++ ) {
      fnt[i] = createFont(font_name[i], fsize[i], true);
    }
  } 
  else {
    // 作成済みのフォントをロードする例
    for ( int i=0; i<font_file.length; i++ ) {
      fnt[i] = loadFont(font_file[i]);
    }
  }

  colorMode(RGB, 256, 256, 256); // カラーモードをRGBに
  background(255);     // 背景色を指定
  smooth();            // 以後アンチエイリアス有効

  // 事前に時計盤を描画して作成しておく
  pg = createGraphics(width, height, JAVA2D);
  drawWatch(pg, height, fpsv);

  init_lap();  // 時間記録初期化
  irq = false;

  // 表示用フレームレートを指定
  frate_idx = 0;
  frameRate(frate_list[frate_idx]);

  if ( pdf_out == 0 ) {
    loop();
  } 
  else {
    // pdf出力モード時の初期設定
    size(480, 480);
    noLoop();
    beginRecord(PDF, pdf_name);
  }
}

// ----------------------------------------
// 毎フレーム呼ばれる処理
void draw() {
  if ( pdf_out == 0 ) {
    // アニメーションモード
    int w = height;

    noSmooth();
    image(pg, 0, 0 );       // 時計盤を描画
    // drawWatch(null, height);
    smooth();

    long nt = System.nanoTime();
    long dt;
    if ( watching ) { // 秒針動作中
      dt = totaltime + (nt - starttime);
    } 
    else { // 秒針停止中
      dt = totaltime;
    }

    int cx = w / 2;
    int cy = w / 2;

    translate(cx, cy); // 画像の中心を(0,0)として設定
    drawSecondHandNano(dt, (w * 0.88) / 2); // 秒針を描画
    translate(-cx, -cy); // 画像の左上を(0,0)として設定

    // デジタル表示で時間を描画
    noSmooth();
    drawText(get_time_str(conv_m2f(dt)), cx, cy + w/6, 1, false);

    // 「RESET」を描画
    drawText2("RESET", 4, height - 16 - fsize[1], 1, true);
    if (lap_draw != 0) {
      drawLap();           // LAPを描画
    }

    draw_msg(); // メッセージを描画

    // FPSを描画
    float nfr = frameRate;
    int tfr = frate_list[frate_idx];
    drawText2(nf(nfr, 2, 2) + "/" + tfr + "FPS", 0, 0, 1, false);
    drawFpsBar(nfr, tfr, 84, 4, 100);
  }
  else {
    // pdf出力モード
    drawWatch(null, height, fpsv);
    endRecord();
    exit();
  }
}

// ----------------------------------------
// キーが押された時の処理
void keyPressed() {
  if ( irq ) {
    return;
  }
  irq = true;
  long ntime = System.nanoTime();
  int mode = 0;
  if (key == 'c') {
    // cキーが押された
    mode = 2; // 「RESET」を要求しておく
  } 
  else if (key == 'x') {
    // xキーが押された
    mode = 1; // START/STOP切り替え要求をしておく
  }
  else if (key == 'o') {
    // oキーが押された
    // 記録をテキストファイルとして出力
    output_textfile_lap();
  }
  else if (key == 'p') {
    // pキーが押された
    // フレームレートを変更する
    init_lap();
    frate_idx = (frate_idx + 1) % frate_list.length;
    frameRate(frate_list[frate_idx]);
    loop();
  }
  else if (key == '@') {
    // @キーが押された
    // 24コマ/秒と30コマ/秒を切り替える
    fpsv = (fpsv == 24)? 30 : 24;
    drawWatch(pg, height, fpsv);
    mode = 2;
  }
  else if (key == '/') {
    // 「/」キー(「?」キー)が押された
    // Verison情報を表示
    set_msg(verinfo);
  }
  else {
    if (watching) { // 秒針が動いてる
      mode = 3; // LAPを要求しておく
    } 
    else { // 秒針が止まってる
      mode = 1; // START/STOP切り替え要求をしておく
    }
  }
  if ( mode > 0 ) {
    set_time(ntime, mode);
  }
  irq = false;
}

// 秒針の制御
void set_time(long ntime, int mode) {
  switch(mode) {
  case 0:
    break;
  case 1:
    // START/STOP切り替え要求
    if ( watching ) {
      // 秒針が動いている
      totaltime += (ntime - starttime);
      watching = false;
      save_lap(totaltime);
    } 
    else {
      // 秒針が止まっている
      start_watching(ntime);
    }
    break;
  case 2:
    // RESET要求
    init_lap();
    break;
  case 3:
    // 記録を要求
    if ( watching ) {
      // 秒針が動いている
      save_lap(totaltime + (ntime - starttime));
    } 
    else {
      // 秒針が止まっている
      start_watching(ntime);
    }
  }
}

// 秒針を動かし始める
void start_watching(long ntime) {
  starttime = ntime;
  watching = true;
}

// ナノ秒をフレーム数に変換
long conv_m2f(long ntime) {
  return int(fpsv * ntime / 1e+9);
}

// 時間記録初期化
void init_lap() {
  frm = 0;          // フレームカウンタクリア
  watching = false; // 秒針を止める
  starttime = 0;
  totaltime = 0;
  lapidx = 0;
  for (int i=0; i<lap.length; i++ ) {
    lap[i] = 0;
  }
}

// 時間を記録
void save_lap(long ntime) {
  lap[lapidx] = ntime;
  lapidx = (lapidx + 1) % lap.length;
}

// ----------------------------------------
// マウスボタンが押された時の処理
void mousePressed() {
  if ( irq ) {
    return;
  }
  irq = true;
  long ntime = System.nanoTime();
  int mode = 0;
  if ( (mouseX < 58) && (mouseY > height-28) ) {
    // 画面の右下をクリックされたなら
    mode = 2; // RESET
  } 
  else if ( mouseButton == LEFT ) {
    // マウス左ボタンが押された
    mode = (watching)? 3 : 1;
  }
  else if ( mouseButton == RIGHT ) {
    // マウス右ボタンが押された
    mode = 1; // START/STOP切り替え
  }
  else if ( mouseButton == CENTER ) {
    // マウス中ボタンが押された
    mode = 2; // RESET
  }
  if ( mode > 0 ) {
    set_time(ntime, mode);
  }
  irq = false;
}

// ----------------------------------------
// 時計盤を描画する
void drawWatch(PGraphics pg, int w, int lfps) {

  // 円の幅を算出
  // 画面サイズに対する割合で直径を記述
  float[] r = {
    0.95, // 0, 最も外側の円の下地
    0.9, // 1, 最も外側の円の線
    0.84, // 2, 2番目の円の線
    0.81, // 3, 3番目の円の線
    0.78, // 4, 1秒を4分割する目盛の線の内径
    0.76, // 5, 秒を示す目盛の線の内径
    0.68, // 6, 秒を示す数字の配置位置
    0.73, // 7, 「6,12,18」の数字の配置位置
    0.55 // 8, 秒の横の小さい秒数文字の配置位置
  };

  // 目盛線の太さ
  float[] lw = {
    1.0, 1.0, 1.0, 2.0
  };

  // 目盛線の色(明度)
  int[] lv = {
    0, 0, 0, 0
  };

  // 目盛を描く際の、何番目の半径を参照するか
  int[] ridx = {
    2, 3, 4, 5
  };

  // 画面サイズに足しうる割合を使って、直径を求めておく
  for ( int i=0; i<r.length; i++) {
    r[i] *= w;
  }

  if ( pg != null ) {
    pg.beginDraw();
    pg.background(255);        // 背景をクリア
    pg.translate(w/2, w/2);    // 画像の中心を(0,0)として設定
    pg.smooth();

    // 円を描く
    pg.noFill(); // 以後塗り潰しはしない
    pg.stroke(0); // 線の色を指定
    pg.strokeWeight(2.0); // 線の太さを指定
    pg.ellipse(0, 0, r[1], r[1]); // 円を描く
    pg.strokeWeight(0.8);
    pg.ellipse(0, 0, r[2], r[2]);
    pg.ellipse(0, 0, r[3], r[3]);
  } 
  else {
    background(255);
    translate(w/2, w/2);
    smooth();

    noFill();
    stroke(0);
    strokeWeight(2.0);
    ellipse(0, 0, r[1], r[1]);
    strokeWeight(0.8);
    ellipse(0, 0, r[2], r[2]);
    ellipse(0, 0, r[3], r[3]);
  }


  // 以後、目盛の線を描いていく

  // 計算に使うのは直径ではなく半径なので、全部2で割っておく
  for ( int i=0; i < r.length ; i++ ) {
    r[i] /= 2;
  }

  int cnt = lfps * 6; // 6秒分の目盛線の個数を決定
  int d0 = lfps / 4;  // 1秒を4分割するための値
  int d1 = d0 / 2;    // 1秒を4分割した上に更に2分割するための値
  if (lfps == 30) { // 30fpsの場合は分割の仕方を変える
    d0 = lfps / 3;    // 1秒を3分割
    d1 = d0 / 2;      // 1秒を3分割、したものを2分割
  }

  // 目盛の線の個数分繰り返す
  for ( int i=0; i< cnt; i++ ) {
    float ang = radians(360.0 * i / cnt - 90);  // 角度を算出
    float x0 = r[1] * cos(ang); // 線の開始座標を算出
    float y0 = r[1] * sin(ang);

    int mode = 0;
    if ( i % lfps == 0 ) {
      mode = 3; // 秒単位の目盛
    } 
    else if ( i % d0 == 0 ) {
      mode = 2; // 1秒を4分割した目盛
    } 
    else if ( i % d1 == 0) {
      mode = 1; // 1秒を4分割、した上に2分割した目盛
    }
    float x1 = r[ridx[mode]] * cos(ang); // 線の終点座標を算出
    float y1 = r[ridx[mode]] * sin(ang);

    if ( pg != null ) {
      pg.noFill();               // 塗り潰し無し
      pg.stroke(lv[mode]);       // 線の色を指定
      pg.strokeWeight(lw[mode]); // 線の太さを設定
      pg.strokeCap(SQUARE);      // 線の端を丸くしない
      // strokeCap(PROJECT);     // 線の端を丸くしない
      pg.line(x0, y0, x1, y1);   // 線を引く
      pg.strokeCap(ROUND);       // 線の端を丸くする
    } 
    else {
      noFill();               // 塗り潰し無し
      stroke(lv[mode]);       // 線の色を指定
      strokeWeight(lw[mode]); // 線の太さを設定
      strokeCap(SQUARE);      // 線の端を丸くしない
      line(x0, y0, x1, y1);   // 線を引く
      strokeCap(ROUND);       // 線の端を丸くする
    }

    // 以後、文字を描画

    switch(mode) {
    case 2:
      // 1秒を4分割した数字を描画
      int v = i % lfps;
      if ( v != 0 ) {
        float x = r[7] * cos(ang);
        float y = r[7] * sin(ang);
        if ( pg != null ) {
          drawTextPg(pg, str(v), x, y, 1, false);
        } 
        else {
          drawText(str(v), x, y, 1, false);
        }
      }
      break;

    case 3:
      // 秒の数字を描画
      int n = i / lfps; // 秒数の値を得る
      if ( n == 0 ) {
        n = 6; // 「0秒」は「6秒」として数字を描く
      }
      float x = r[6] * cos(ang);
      float y = r[6] * sin(ang);
      if ( pg != null ) {
        drawTextPg(pg, str(n), x, y, 0, true);
      } 
      else {
        drawText(str(n), x, y, 0, true);
      }

      // 小さい数字
      if ( n != 6 ) {
        n += 6; // 6秒、数値を増やす
        float xs = r[8] * cos(ang);
        float ys = r[8] * sin(ang);
        if ( pg != null ) {
          drawTextPg(pg, str(n), xs, ys, 1, false);
        } 
        else {
          drawText(str(n), xs, ys, 1, false);
        }
      }
      break;
    default:
      break;
    }
  }

  if ( pg != null ) {
    pg.stroke(0);
    pg.strokeWeight(1.0);
    pg.noFill();
    pg.translate(-w/2, -w/2);  // 画像の左上を(0,0)として設定
    pg.endDraw();
  } 
  else {
    stroke(0);
    strokeWeight(1.0);
    noFill();
    translate(-w/2, -w/2);  // 画像の左上を(0,0)として設定
  }
}

// ----------------------------------------

// 文字列を描画する(中心位置を指定するタイプ)
void drawText(String s, float x, float y, int font_kind, boolean shadow) {
  textFont(fnt[font_kind], fsize[font_kind]);
  int ftop = int(textAscent());
  int fbottom = int(textDescent());
  float w = textWidth(s);  // 文字列の幅(ドット数)を取得
  float h = ftop+fbottom;  // 文字列の高さ(ドット数)を算出
  x -= (w / 2); // 表示位置を算出
  y += (ftop - h / 2);
  noStroke();
  if (shadow) {
    // 影を描画
    fill(204);
    text(s, x+2, y+2); // 文字列描画
  }
  fill(0);
  text(s, x, y); // 文字列描画
}

// 文字列をPGraphicsに描画する(中心位置を指定するタイプ)
void drawTextPg(PGraphics pg, String s, float x, float y, int font_kind, boolean shadow) {
  pg.textFont(fnt[font_kind], fsize[font_kind]);
  int ftop = int(pg.textAscent());
  int fbottom = int(pg.textDescent());
  float w = pg.textWidth(s);  // 文字列の幅(ドット数)を取得
  float h = ftop+fbottom;  // 文字列の高さ(ドット数)を算出
  x -= (w / 2); // 表示位置を算出
  y += (ftop - h / 2);
  pg.noStroke();
  if (shadow) {
    // 影を描画
    pg.fill(204);
    pg.text(s, x+2, y+2); // 文字列描画
  }
  pg.fill(0);
  pg.text(s, x, y); // 文字列描画
}

// 文字列を描画する(左上位置を指定するタイプ)
void drawText2(String s, float x, float y, int font_kind, boolean basefg) {
  textFont(fnt[font_kind], fsize[font_kind]);
  int ftop = int(textAscent());
  int fbottom = int(textDescent());
  float w = textWidth(s);
  float h = ftop+fbottom;
  int xa = 0;
  int ya = 0;
  if (basefg) {
    // ボタンの下地を描画
    fill(204);
    stroke(128);
    rect(x, y, w+8, h+8);
    xa = 4;
    ya = 4;
  }
  y = y + ftop;
  fill(0);
  noStroke();
  text(s, x+xa, y+ya); // 文字列描画
}

// ----------------------------------------
// 秒針を描画する(ナノ秒を与える版)
void drawSecondHandNano(long ntime, float rw) {
  // noSmooth();
  smooth();
  long c = 6000000000L;

  // 時間記録分の秒針を描く
  if (lap_draw != 0) {
    int j = (lapidx + lap.length - 1) % lap.length; // 記録参照用インデックス値
    long n = lap[j];           // 記録を得る
    int alpha = 32 + 8 * 16;  // 初期透明度
    strokeWeight(1.0);
    noFill();
    while ( alpha >= 32 && n > 0 && ( (ntime - n) < c) ) {
      // 記録と現在フレームが異なるなら、半透明な針を描画
      if ( n != ntime ) {
        float ang = radians((n % c) * 360.0 / c - 90);
        float x = rw * cos(ang);
        float y = rw * sin(ang);
        // alpha は透明度(255で不透明、0で完全に透明)
        stroke(0, 0, 255, alpha);
        line(0, 0, x, y);
      }
      j--;
      if ( j < 0 ) {
        j += lap.length;
      }
      n = lap[j];  // 次の記録を取得
      alpha -= 8;  // より透明にしていく
    }
  }

  float ang = radians((ntime % c) * 360.0 / c - 90);
  float x = rw * cos(ang);
  float y = rw * sin(ang);

  // 秒針を描く
  stroke(255, 0, 0);
  strokeWeight(2.0);
  noFill();
  line(0, 0, x, y);

  // 秒針の真ん中の小さな円を描く
  noStroke();
  fill(255, 0, 0);
  ellipse(0, 0, 8, 8);

  strokeWeight(1.0);
}  

// ----------------------------------------
// 時間を示す文字列を取得する
String get_time_str(long frm) {
  int koma = int(frm % fpsv);
  frm -= koma;
  int hh = int(frm / (360 * fpsv)) % 100;
  int mm = int(frm / (60 * fpsv)) % 60;
  int ss = int(frm / fpsv) % 60;
  return nf(hh, 2) + ":" + nf(mm, 2) + ":" + nf(ss, 2) + "+" + nf(koma, 2);
}

// ----------------------------------------
// 時間記録を描画する
void drawLap() {
  int fs = fsize[1];
  int j = (lapidx + lap.length -1) % lap.length;
  int x = height;
  int y = height - fs - 16;
  int fh = fs + 6;
  int cnt = int(height / fh) - 2;
  for ( int i=0; i<cnt; i++ ) {
    int nj = j - 1;
    if ( nj < 0 ) {
      nj += lap.length;
    }
    long now = conv_m2f(lap[j]);
    long old = conv_m2f(lap[nj]);
    long d = now - old;
    drawText2(get_time_str(now) + " (+" + get_time_str(d) + ")", x, y, 1, false);
    if ( now == 0 ) {
      break;
    }
    y -= fh;
    j = nj;
  }
}

// ----------------------------------------
// 記録をテキストファイルに保存
void output_textfile_lap() {
  if ( online ) {
    set_msg("Can not save the file.");
    return;
  }
  if ( msg_disp_cnt > 0 ) {
    return;
  }

  String[] lines = new String[lapidx+1];
  long old = 0;
  long n = 0;
  for (int i=0; i<=lapidx; i++ ) {
    long d = n - old;
    lines[i] = get_time_str(n) + ",,#(+ " + get_time_str(d) + ")";
    old = n;
    n = conv_m2f(lap[i]);
  }
  saveStrings(log_filename, lines);
  set_msg(log_filename + " saved.");
}

// ----------------------------------------
// メッセージ描画
void draw_msg() {
  if ( msg_disp_cnt > 0 ) {
    fill(255);
    stroke(128);
    strokeWeight(2.0);
    int cx = width / 2;
    int cy = height / 2;
    int w = width * 4 / 5;
    int h = fsize[1] * 4;
    rect(cx - w/2, cy - h/2, w, h);
    drawText(msg, cx, cy, 1, false);
    msg_disp_cnt--;
  }
}

// メッセージ登録
void set_msg(String s) {
  msg = s;
  msg_disp_cnt = fpsv * 3;
}

// ----------------------------------------
// 実フレームレートをグラフで表示
void drawFpsBar(float nfr, float tfr, int x, int y, int wb) {
  float w0 = tfr * wb / tfr;
  float w1 = nfr * wb / tfr;
  noSmooth();
  noStroke();
  fill(0, 255, 0);
  rect(x, y, w0, 8);
  fill(255, 0, 0);
  rect(x, y + 4, w1, 4);
}